Question

这个问题与

有关

XSLT to generate html tags specified in XML

我有一个xml docment并使用xsl使用

生成html标签

<xsl:element name="{Type}" >

我遇到的问题是我想在我的xml中指定一些html属性，例如

<Page>
  <ID>Site</ID>
  <Object>
    <ID>PostCode</ID>
    <Type>div</Type>
    <Attributes>
       <Attribute name="class">TestStyle</Attribute>
       <Attribute name="id">TestDiv</Attribute>
    </Attributes>
    <Class>display-label</Class>
    <Value>PostCode</Value>
  </Object>
</Page>

那么有没有人知道如何使用xsl用两个属性填充xsl：元素？

由于

Answer 1

根据stylesheet that I posted in the previous question构建，在元素声明中，您可以遍历每个Attributes/Attribute元素，并为< 构建属性你正在构建的em>元素。

您正站在for循环中的Object元素节点上，因此您可以迭代它的Attributes/Attribute元素，如下所示：

<xsl:for-each select="Attributes/Attribute">
  <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
</xsl:for-each>

应用于您的样式表：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:for-each select="Page/Object">
            <xsl:element name="{Type}" >
                <xsl:for-each select="Attributes/Attribute">
                    <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
                </xsl:for-each>
                <xsl:value-of select="Value"/>
            </xsl:element>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

这是实现相同输出的另一种方法，但是使用apply-templates代替for-each以更加妄想的方式。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:apply-templates select="Page/Object" />
      </body>
    </html>
  </xsl:template>

  <xsl:template match="Object">
    <xsl:element name="{Type}" >
       <xsl:apply-templates select="Attributes/Attribute" />
       <xsl:apply-templates select="Value" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="Attribute">
     <xsl:attribute name="{@name}"><xsl:value-of select="."/></xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

Answer 2

您需要修复源示例中的Attributes元素，它才会关闭。

您可以xsl:for-each或xsl:apply-templates使用select="Attributes/Attribute"来调用看起来像这样的xsl:attribute元素：

<xsl:attribute name="{@name}"><xsl:value-of select="text()"/></xsl:attribute>

您需要注意的事项是xsl:attribute必须先出现在将{child}添加到{Type}元素的任何内容之前。

Answer 3

<xsl:element name="Attribute">
  <xsl:attribute name="class">TestStyle</xsl:attribute>
  <xsl:attribute name="id">TestDiv</xsl:attribute>
</xsl:element>

xsl：element apply属性

3 个答案: