Question

我只想列出使用（：跳转列表）时我刚刚找到的最新动作位置（比方说，10或更少），默认值100太大，我必须翻到最近的。

Answer 1

首先，没有命令:jumplist，我想你的意思是:jumps

该设置没有选项。但你可以做的是，像往常一样:jumps，当显示“长”列表时，按G会将你带到最新的列表。

Answer 2

这是:Tail（以及相应的:Head）命令的定义，它允许您将任何Vim命令的输出限制为10行：

:Tail jumps
(showing only the last 10 jumps)

Scriptlet中

":[N]Head {cmd}     Show only the first 10 / [N] lines of {cmd}'s output.
":[N]Tail {cmd}     Show only the last 10 / [N] lines of {cmd}'s output.
function! s:CaptureCommand( command )
    redir => l:commandOutput
        silent! execute a:command
    redir END
    redraw  " This is necessary because of the :redir done earlier.
    return split(l:commandOutput, "\n")
endfunction
function! s:Head( count, command )
    let l:lines = s:CaptureCommand(a:command)
    for l:line in l:lines[0:(a:count ? a:count : 10)]
        echo l:line
    endfor
endfunction
function! s:Tail( count, command )
    let l:lines = s:CaptureCommand(a:command)
    for l:line in l:lines[-1 * min([(a:count ? a:count : 10), len(l:lines)]):-1]
        echo l:line
    endfor
endfunction
command! -range=0 -nargs=+ Head call <SID>Head(<count>, <q-args>)
command! -range=0 -nargs=+ Tail call <SID>Tail(<count>, <q-args>)

我可以配置跳转列表中条目的最大数量

2 个答案:

Scriptlet中

更多想法