Question

我有一个与Show相同的类，我想为每个元组类型创建一个这个类的实例。通常这是通过为每个元组类型单独编写实例来完成的

instance  (Show a, Show b) => Show (a,b)  where
  showsPrec _ (a,b) s = show_tuple [shows a, shows b] s

instance (Show a, Show b, Show c) => Show (a, b, c) where
  showsPrec _ (a,b,c) s = show_tuple [shows a, shows b, shows c] s

instance (Show a, Show b, Show c, Show d) => Show (a, b, c, d) where
  showsPrec _ (a,b,c,d) s = show_tuple [shows a, shows b, shows c, shows d] s
...

为每个元组类型编写一个实例会产生大量的样板，并且很容易看到所有showPrec实现之间共享的公共模式。为了避免这种样板，我想我可以使用Data.Generics中的Scrap your boilerplate并实现折叠元组，例如

showTuple = intercalate " " . gmapQ ("" `mkQ` show)

但是showTuple因某种原因无效

> showTuple (1,2)
" "

我认为问题在于show是多态的，因为如果我专注showTuple那么它可以工作

showTupleInt = intercalate " " . gmapQ ("" `mkQ` (show :: Int -> String))

> showTupleInt (1::Int,2::Int)
"1 2"

我已经检查了gshow的代码，它做了类似于我需要的东西，但我无法弄清楚它是如何工作的。如果我尝试将其代码导入GHCI，我会收到错误：

> let gshows = (\t -> showChar '('
                      . (showString . showConstr . toConstr $ t)
                      . (foldr (.) id . gmapQ ((showChar ' ' .) . gshows) $ t)
                      . showChar ')'
                      ) `extQ` (shows :: String -> ShowS)
<interactive>:262:59:
Could not deduce (a ~ d)
from the context (Data a)
  bound by the inferred type of
           gshows :: Data a => a -> String -> String
  at <interactive>:(259,5)-(264,44)
or from (Data d)
  bound by a type expected by the context:
             Data d => d -> String -> String
  at <interactive>:262:33-65
  `a' is a rigid type variable bound by
      the inferred type of gshows :: Data a => a -> String -> String
      at <interactive>:259:5
  `d' is a rigid type variable bound by
      a type expected by the context: Data d => d -> String -> String
      at <interactive>:262:33
Expected type: d -> String -> String
  Actual type: a -> String -> String
In the second argument of `(.)', namely `gshows'
In the first argument of `gmapQ', namely
  `((showChar ' ' .) . gshows)'
In the second argument of `(.)', namely
  `gmapQ ((showChar ' ' .) . gshows)'

所以我有两个问题：

showTuple出了什么问题？如何修复它以便它可以处理任何大小的元组
gshow如何工作以及为什么如果我在GHCI上导入代码我会收到错误？

编辑：我正在研究Data.Generics和一般的SYM，所以我想使用该模块。只有在使用该模块时我才会接受答案。感谢。

Answer 1

我对GHC Generics更熟悉，而不是SYB，所以我提供了一个基于Generics的解决方案。虽然它没有直接回答你的问题，但我希望它也有用。

{-# LANGUAGE TypeOperators, FlexibleContexts, DefaultSignatures #-}
import Data.Sequence
import GHC.Generics

class Strs' f where
    strings' :: f a -> Seq String

instance Strs' U1 where
    strings' U1 = empty

instance Show c => Strs' (K1 i c) where
    strings' (K1 a) = singleton $ show a

instance (Strs' a) => Strs' (M1 i c a) where
    strings' (M1 a) = strings' a

instance (Strs' f, Strs' g) => Strs' (f :*: g) where
    strings' (a :*: b) = strings' a >< strings' b

class Strs a where
    strings :: a -> Seq String
    default strings :: (Generic a, Strs' (Rep a)) => a -> Seq String
    strings = strings' . from

-- Since tuples have Generic instances, they're automatically derived using
-- the above default.
instance Strs () where
instance (Show a, Show b) => Strs (a, b) where
instance (Show a, Show b, Show c) => Strs (a, b, c) where

Answer 2

由于showTuple的多态性，show不起作用，你是对的。问题是mkQ想要选择一种特定的类型：

mkQ :: (Typeable a, Typeable b) => r -> (b -> r) -> a -> r

类型签名中的b必须是mkQ每次使用的一种特定类型 - 没有类型签名，默认规则可能会选择一些东西（不确定是什么！），而使用它选择的类型签名Int。

您的showTupleInt适用于任何大小的元组，但当然不适用于任何类型的元组。

在GHCi中定义gshows的问题在于它确实需要一个类型签名才能进行类型检查，因为gshows在其自己的定义中以不同的类型递归使用原始的调用。如果没有类型签名，类型检查器希望gshows的定义与使用gshows具有完全相同的类型变量实例 - 它显示为Could not deduce (a ~ d)类型错误。

你可以通过将它放在带有和不带有类型签名的源文件中来看到这一点 - 如果你第一次使用:set -XNoMonomorphismRestriction，那么你可以使用签名来检查它是否正确，如果没有它你会得到类似的错误

由于gshows：

的类型，

gmapQ可以正常工作

gmapQ :: Data a => (forall d. Data d => d -> u) -> a -> [u]

与mkQ相比，它所采用的参数本身就是多态的 - 请注意嵌套的forall。

虽然您的showTuple也使用gmapQ，但为时已晚mkQ已迫使问题show只能处理一种类型。

您也无法直接使用show gmapQ直接使用gmapQ，因为约束条件不同 - Data需要能够在show的任何实例上使用的内容，而Show {1}}受gshows约束。 Show从未真正使用shows类型类，但它确实使用String专门用于showTuple。

在这样的情况下很难证明是负面的，但是我很确定你不能写Show之类的任何东西，只会使用{{1}多态地使用syb类因为它根本没有任何可以“识别”具有特定实例的类型的东西。这就是syb-with-class存在的原因。

另外，如果你真的想要一些只适用于单一类型结构的东西，即显示任何大小的元组但是对元组的元素使用其他东西，那么syb可能是错误的解决方案因为它设计用于递归操作并在任何级别的数据结构中查找内容。我的观点是GHC.Generics解决方案是实施showTuple最好的解决方案。

Answer 3

您可以使用syb-with-class。它早于-XConstraintKinds，因此您需要编写Sat的实例 class并派生此库派生的Data类。这是一个例子，这非常接近showTuple示例，除了我添加了一些{}：

{-# LANGUAGE FlexibleContexts, FlexibleInstances, MultiParamTypeClasses, TemplateHaskell, UndecidableInstances #-}
import Data.Generics.SYB.WithClass.Basics
import Data.Generics.SYB.WithClass.Instances
import Data.Generics.SYB.WithClass.Derive

data A a b c = A a b c deriving Show
data B a = B a deriving Show
data C a = C a deriving Show

derive [''A,''B,''C]

data ShowD a = ShowD { showD :: a -> String -> String }
instance (Show a) => Sat (ShowD a) where
    dict = ShowD shows

gshow x = case gfoldl ctx 
                (\ (s, f) x -> (s . ("{"++) . showD dict x . ("}"++) , f x))
                (\y -> (id ,y))
                x
        of (str,_) -> str ""
    where
        ctx :: Proxy ShowD
        ctx = undefined

x1 = A (B 'b') (C "abc") (B ())

{-
>>> gshow x1
"{B 'b'}{C \"abc\"}{B ()}"

>>> show x1
"A (B 'b') (C \"abc\") (B ())"
-}

gfoldl的第二个参数可以调用shows (B 'b')，shows (C "abc") 和shows (B ())感谢获得showD dict功能的shows 正确的类型。

Haskell中的通用编程，具有SYB和ad-hoc多态性

3 个答案: