Question

我需要从应用程序生成Outlook并使用Outlook发送消息。邮件表单应显示为模式，主要是因为我生成附件，当用户发送电子邮件（或丢弃它）时应将其删除。

我的问题是当我进行Outlook对话框模式（“MailIt.Display（True）”）时，Outlook消息窗口显示在后台。命令“Outlook.ActiveWindow.Activate”将它带到前面，但是当窗口已经可见时可以调用它，所以如果窗口是模态的话我就不能调用它。我试过这段代码：

MailIt.Display(False);
OleVariant(Outlook.ActiveWindow).Activate;
MailIt.Display(True);

但是id不起作用，如果表单已经显示正常模式，则无法切换到模态。有任何想法吗？我的环境：Windows 8（禁用UAC），XE3，Outlook 2010。

尝试按照Arioch的建议将表单发送到背景中：

SetWindowPos(AWnd, HWND_BOTTOM, 0, 0, 0, 0, SWP_NOMOVE or SWP_NOSIZE);
MailIt.Display(AModal);
SetForegroundWindow(AWnd);

在这种情况下，Outlook成为前景（因为我需要它），但我的来自可以变得不可见（如果有其他正在运行的应用程序打开表单），所以它也无法解决问题。它应该是顶部的模态状态的Outlook，我的应用程序是Outlook旁边。

SetWindowPos(AWnd, HWND_NOTOPMOST, 0, 0, 0, 0, SWP_NOMOVE or SWP_NOSIZE)

比HWND_BOTTOM更好，但不能保证Outlook成为前景。

EDITED2。基于事件的最终（希望）解决方案（来自Kobik的建议）：

uses
  Vcl.OleServer, Winapi.ActiveX;

Type
  TOutlookMsgForm = class
  private
  protected
    FOutlook: OutlookApplication;
    FMessageSent: Boolean;

    procedure OnOpen(ASender: TObject; var Cancel: WordBool);
    procedure OnSend(ASender: TObject; var Cancel: WordBool);
    function  TryDisplayOutlookMail(const AMailTo, ASubject, ABody: string;
      const AAttachmentFileNames: array of string; AWnd: HWND; AModal: Boolean): boolean;

    property Outlook: OutlookApplication read FOutlook write FOutlook;
    property MessageSent: Boolean read FMessageSent write FMessageSent;
  public
    class function DisplayOutlookMail(const AMailTo, ASubject, ABody: string;
      const AAttachmentFileNames: array of string; AWnd: HWND; AModal: Boolean = True): boolean; static;
  end;

{ TOutlookMsgForm }

procedure TOutlookMsgForm.OnOpen(ASender: TObject; var Cancel: WordBool);
begin
  if (Outlook<>nil) and (Outlook.ActiveWindow<>nil) then
    OleVariant(Outlook.ActiveWindow).Activate;
end;

procedure TOutlookMsgForm.OnSend(ASender: TObject; var Cancel: WordBool);
begin
  Cancel := False;
  MessageSent := True;
end;

function TOutlookMsgForm.TryDisplayOutlookMail(const AMailTo, ASubject, ABody: string;
  const AAttachmentFileNames: array of string; AWnd: HWND; AModal: Boolean): boolean;
var
  MailIt: MailItem;
  Mail: TMailItem;
  i: Integer;
begin
  MessageSent := False;
  try
    OleInitialize(nil);
    try
      Outlook := CoOutlookApplication.Create;
      Mail := nil;
      try
        MailIt := Outlook.CreateItem(olMailItem) as MailItem;
        MailIt.To_ := AMailTo;
        MailIt.Subject := ASubject;
        MailIt.Body := ABody;
        for i := Low(AAttachmentFileNames) to High(AAttachmentFileNames) do
          MailIt.Attachments.Add(AAttachmentFileNames[i], EmptyParam, EmptyParam, EmptyParam);
        Mail := TMailItem.Create(nil);
        Mail.ConnectTo(MailIt);
        Mail.OnOpen := OnOpen;
        Mail.OnSend := OnSend;
        MailIt.Display(AModal);
        if AModal and (AWnd<>0) then
          SetForegroundWindow(AWnd);
        Result := true;
      finally
        FreeandNil(Mail);
        MailIt := nil;
        Outlook := nil;
      end;
    finally
      OleUnInitialize;
    end;
  except
    Result := False;
  end;
end;

所以它解决了（尝试＃3）。谢谢！

Answer 1

如果你不能把Outlook带到前面，也许你可以通过从辅助线程发布消息将你自己的应用程序推到后面？

在Outlook中生成新消息并显示为模式

1 个答案: