Question

假设我有以下函数从字节缓冲区中获取数值：

(defn get-from-bytebuffer
  ([^ByteBuffer buffer width endianness]
    (let [buffer-endianness (.order buffer)]
      (.order buffer endianness)
      (cond
        (= width 1) (.get buffer)
        (= width 2) (.getShort buffer)
        (= width 4) (.getInt buffer)
        (= width 8) (.getLong buffer))
      (.order buffer buffer-endianness))))

用户可以指定正在读取的数字的字节顺序。为了将副作用保持在最小，函数首先获取缓冲区的当前字节顺序，将其设置为用户指示的顺序，然后恢复旧的字节顺序。这个问题是let正文中最后一个表达式的值是let表达式的值，但我需要cond的值。更一般地说，我在表达式周围有一些序言/结尾代码，但我希望返回表达式的结果（是封闭表达式的值。）

我提出的简单解决方法只是将cond的值绑定在另一个let表达式中，然后将其作为最后一个表达式，如下所示：

(defn get-from-bytebuffer-fix
  ([^ByteBuffer buffer width endianness]
    (let [buffer-endianness (.order buffer)]
      (.order buffer endianness)
      (let [result (cond
                     (= width 1) (.get buffer)
                     (= width 2) (.getShort buffer)
                     (= width 4) (.getInt buffer)
                     (= width 8) (.getLong buffer))]
      (.order buffer buffer-endianness)
      result))))

但这感觉很糟糕。 Clojure是否有一种惯用/“正确”的方式用一些序言/结尾代码包围表达式然后返回该表达式的值？

Answer 1

下面的替代方案之一可能是可以接受的。

(let [buffer-endianness (.order buffer)
      _ (.order buffer endianness)
      result (cond
               (= width 1) (.get buffer)
               (= width 2) (.getShort buffer)
               (= width 4) (.getInt buffer)
               (= width 8) (.getLong buffer))
      _ (.order buffer buffer-endianness)]
  result)

(let [buffer-endianness (.order buffer)]
  (try 
    (.order buffer endianness)
    (cond
      (= width 1) (.get buffer)
      (= width 2) (.getShort buffer)
      (= width 4) (.getInt buffer)
      (= width 8) (.getLong buffer))
    (finally (.order buffer buffer-endianness))))

(defn return-nth [n & exprs]
  (nth exprs n))

(return-nth 1
  'exp-0
  'exp-1
  'exp-2)

(nth ['exp-0 'exp-1 'exp-2] 1)

另请注意

(cond
  (= width 1) (.get buffer)
  (= width 2) (.getShort buffer)
  (= width 4) (.getInt buffer)
  (= width 8) (.getLong buffer))

可以写

(case width
  1 (.get buffer)
  2 (.getShort buffer)
  4 (.getInt buffer)
  8 (.getLong buffer))

Answer 2

你可以把它写成：

(defn get-from-bytebuffer
  ([^ByteBuffer buffer width endianness]
    (let [buffer-endianness (.order buffer)
          _ (.order buffer endianness)
          result (cond
                   (= width 1) (.get buffer)
                   (= width 2) (.getShort buffer)
                   (= width 4) (.getInt buffer)
                   (= width 8) (.getLong buffer))]
      (.order buffer buffer-endianness)
      result)))

请注意let表单中的_。它只是忽略了返回值，允许你在那个位置做任何事情。

我不会说它是惯用的，并且在某种程度上它是'奇怪的'因为它在let绑定中有副作用，但我之前在类似的场景中使用过这种风格，到目前为止我很满意它。

否则我已经采用了你所展示的双重方法。

希望这有帮助。

在Clojure中返回表达式序列中非最后一个表达式的值的惯用法

2 个答案: