XSLT - 为什么更改节点上下文不起作用？

Question

XSLT - 为什么更改节点上下文不起作用？

我的源XML文档

我有一个给定的源XML文档，其中包含一个<definition>和一些<override>元素。 <variable>元素中的每个<definition>元素仅对应<assignment>元素中的一个<override>元素。此1：1关系由其<name>元素的内容（ID）建立。

这是我的源XML文档的示例：

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>object01_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>  
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>object01_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
  </override>
</sample>

我的目标XML文档

根据<path>元素内容的模式，在<assignment>元素的<override>元素中，我想添加一个新的<assignment>元素。 <assignment>元素是主要信息。因此，首先，我必须创建一个包含<assignment>和<path>内容的新<name>元素。之后，我必须创建具有相同<variable>内容和特定<name>内容的相应<value>元素。

这是我的目标XML文档的示例（添加 param03 ）：

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>param00_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
    <variable>
      <name>Param03_ID_138368350261919623</name>
      <value>1000</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>param00_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
    <assignment>
      <name>Param03_ID_138368350261919623</name>
      <xpath>module01/object01/param03</xpath>
    </assignment>
  </override>
</sample>

我的XSLT文档

对于身份转换，我选择使用Dimitre Novatchev推荐的细粒度控制身份规则。使用“处理变量分配”下面的代码，我创建了一个新的<assignment>元素及其特定的<path>和<name>内容。之后，使用“处理变量定义”下面的代码，我想将节点上下文更改为<definition>元素，并在最后位置添加一个新的<variable>元素与相应的元素<name>个内容和特定的<value>内容。

这是我的XSLT文档：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:fo="http://www.w3.org/1999/XSL/Format" 
  xmlns:xs="http://www.w3.org/2001/XMLSchema" 
  xmlns:fn="http://www.w3.org/2005/xpath-functions" 
  exclude-result-prefixes="fo xs fn">
  <!--
  global declarations ==========================================================
  -->
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>
  <!-- randomid here is just a fake for sake of simplification -->
  <xsl:variable name="randomid" select="138368350261919623"/>
  <!--
  template for identity ==========================================================
  -->
  <xsl:template match="node()|@*" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()[1]"/>
    </xsl:copy>
    <xsl:apply-templates select="following-sibling::node()[1]"/>
  </xsl:template>
  <!--
  template for variable assignment ===============================================
  -->
  <xsl:template name="variable_assignment">
    <xsl:param name="value_node_name"/>
    <xsl:param name="value_node_path"/>
    <xsl:message select="'processing: variable assignment'"/>
    <xsl:message select="concat('applying name: ', $value_node_name)"/>
    <xsl:message select="concat('applying path: ', $value_node_path)"/>
    <xsl:call-template name="identity"/>
    <assignment>
      <name>
        <xsl:value-of select="$value_node_name"/>
      </name>
      <xpath>
        <xsl:value-of select="$value_node_path"/>
      </xpath>
    </assignment>
  </xsl:template>
  <!--
    template for processing param03 =============================================
  -->
  <xsl:template match="/sample/override[not(assignment
              /path[matches(text(), '.*/object01/param03$')])]
              /assignment[path[matches(text(), '.*/object01$')]]">
    <!-- setting params -->
    <xsl:param name="value_node_name_target">
      <xsl:value-of select="concat('Param03_ID', '_', $randomid)"/>
    </xsl:param>
    <xsl:param name="value_node_path_target">
      <xsl:value-of select="concat(./path, '/param03')"/>
    </xsl:param>
    <xsl:param name="value_node_value_target" select="'1000'"/>
    <!-- processing variable assignment -->
    <xsl:call-template name="variable_assignment">
      <xsl:with-param name="value_node_name" select="$value_node_name_target"/>
      <xsl:with-param name="value_node_path" select="$value_node_path_target"/>
    </xsl:call-template>
    <!-- processing variable definition -->
    <xsl:for-each select="/sample/definition/*[position()=last()]">
        <xsl:message select="'processing: variable definition'"/>
      <xsl:message select="concat('Here we are: ', .)"/>
      <xsl:message select="concat('applying name: ', $value_node_name_target)"/>
      <xsl:message select="concat('applying value: ', $value_node_value_target)"/>
      <xsl:call-template name="identity"/>
      <variable>
        <name>
          <xsl:value-of select="$value_node_name_target"/>
        </name>
        <value>
          <xsl:value-of select="$value_node_value_target"/>
        </value>
      </variable>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

我的错误结果XML文档

我遇到的问题：

使用<xsl:for-each select="/sample/definition/*[position()=last()]">，节点上下文不会按预期更改。新的<variable>元素会在最后位置添加到<override>元素中，而不是按预期添加到<definition>元素中。
此外，<variable>元素中的最后一个<definition>元素将被复制到<override>元素中。

这是我错误的XML文档，我在转换后得到了如上所述：

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>object01_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>object01_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
    <assignment>
      <name>Param03_ID_138368350261919623</name>
      <xpath>module01/object01/param03</xpath>
    </assignment>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
    <variable>
      <name>Param03_ID_138368350261919623</name>
      <value>1000</value>
    </variable>
  </override>
</sample>

我需要的帮助

如果有人能给我建议，我真的很感激，我必须调整我的XSLT文档，以便按照描述更改节点上下文。（上面列出的所有代码都是使用Saxon HE 9.5创建和测试的。）

非常感谢。

关于你的问题，这是我目前创建随机ID的解决方案（为了简化而不是假的）：

<xsl:stylesheet 
    version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:fn="http://www.w3.org/2005/xpath-functions" 
    xmlns:math="java:java.lang.Math" 
    exclude-result-prefixes="xs fn math">

    <xsl:variable name="baseid" 
                  select='format-number((((math:random() * 
                      10000000000000) mod 10000000000000) + 
                      10000000000000), "#")'/>

</xsl:stylesheet>

由于应用xmlns:math="java:java.lang.Math"，此解决方案需要 Saxon PE 。它运行稳健而快速，但我并不完全满意。源XML文档中存在的ID增加1.因此，我想编写一个解决方案，选择具有最高值的现有ID的ID，将其作为基准值，并根据该ID创建进一步的ID。这样的解决方案将利用源XML文档的现有ID，看起来很简单，另外还可以运行 Saxon HE 许可证。那项任务仍在我的待办事项清单上。

Answer 1

我可能在这里遗漏了一些东西，因为在我看来这可能更简单：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >

<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>


<!-- fakes for sake of simplification -->
<xsl:variable name="randomid" select="'138368350261919623'"/>
<xsl:variable name="next_variable_value" select="1000"/>


<xsl:template match="/sample"> 
    <xsl:copy>
        <xsl:apply-templates select="definition"/>
        <xsl:apply-templates select="override"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="definition"> 
    <xsl:copy>
        <xsl:for-each select="variable">
            <xsl:copy-of select="."/>
        </xsl:for-each>
        <variable>
            <name>
                <xsl:value-of select="concat('Param03_ID_', $randomid)"/>
            </name>
            <value>
                <xsl:value-of select="$next_variable_value"/>
            </value>
        </variable>
    </xsl:copy>
</xsl:template>

<xsl:template match="override"> 
    <xsl:copy>
        <xsl:for-each select="assignment">
            <xsl:copy-of select="."/>
        </xsl:for-each>
        <assignment>
            <name>
                <xsl:value-of select="concat('Param03_ID_', $randomid)"/>
            </name>
            <xpath>module01/object01/param03</xpath>
        </assignment>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

当然，更有趣的部分是＆＃34;为了简化而假货＃34;将被制作。

XSLT - 为什么更改节点上下文不起作用？

XSLT - 为什么更改节点上下文不起作用？

1 个答案: