Question

我只想确认一下我所看到的。下面是我编写的Stored Proc概念的一个小概念，它说明了我在一个更大的问题中遇到的问题。

ALTER PROCEDURE TestErrorHandling
    @Param1 varchar(1) = ''  
AS
BEGIN
/*
Unit test: 
   DECLARE @returnStatus nvarchar(15);
   Exec @returnStatus = TestErrorHandling 
   print @returnStatus    
*/ 

BEGIN TRY   
    print 'Start' 
    IF @Param1 = '' raiserror( '@Param1 is missing', 18, 1 );
    print 'Should not see this' 

END TRY
BEGIN CATCH
    print error_message() 
    print error_state()
    print error_number()
    INSERT INTO [FlightOrderUploadFailedLog]
           (EvtTyp) 
           VALUES ('max size of EvtType is only varchar(15) so this should cause truncation') 
    print 'after insert '
    print error_message() 
    print error_state()
    print error_number()
    return  -- added in second version (after original post) 

END CATCH 

END
GO

输出：

开始

@Param1 is missing
1
50000
Msg 8152, Level 16, State 4, Procedure TestErrorHandling, Line 30
String or binary data would be truncated.
The statement has been terminated.
after insert 
@Param1 is missing
1
50000
-8

对我来说令人惊讶的是，程序没有爆炸“字符串或二进制数据会被截断”。换句话说，之后的代码仍然运行。此外，catch块中的SQL错误不会更改error_message。

所以问题是 - 在“BEGIN CATCH”部分处理意外错误的最佳做法是什么？我应该有另一个嵌套的TRY / CATCH吗？

注意：这是我原来的问题，但是我想把这个问题放在一边，让它脱离主题并混淆问题。在得到答案后，我会回去更新那个：T-SQL Clear Errors

第2部分 - 稍后补充：

   DECLARE @returnStatus nvarchar(15);
   Exec @returnStatus = TestErrorHandling 
   print @returnStatus

返回-8。哎-8来自哪里？

我也在尝试添加“返回”与“返回0”。当BizTalk调用存储过程时，我希望他认为它已成功完成，以免每5分钟进行3次重试。

补充：我认为这主要是我正在寻找的答案： SQL try-catch statement not handling error (SQL Server 2008)

但它没有讨论我在这个问题中提出的最佳实践问题。

更新：这是演示Allan回应的程序：

ALTER PROCEDURE TestErrorHandling2
    @Param1 varchar(1) = ''  
AS
BEGIN
/*
Unit test: 
   DECLARE @returnStatus nvarchar(15);
   Exec @returnStatus = TestErrorHandling2 
   print @returnStatus

This is proof of concept on error handling.   
See question: https://stackoverflow.com/questions/20245900/t-sql-is-error-handling-totally-turned-off-in-a-begin-catch-block    
Testing to see if Truncation error stops or not. 

*/ 

    print 'Start' 

    INSERT INTO [FlightOrderUploadFailedLog]
           (EvtTyp) 
           VALUES ('max size of EvtType is only varchar(15) so this should cause truncation') 
    print 'after insert #1' 
    print 'Message=' + IsNull(error_message(),'null') 
    print 'State=' + IsNull(convert(varchar(4),error_state()),'null') 
    print 'ErrorNumber=' + IsNull(convert(varchar(8),error_number()),'null') 


BEGIN TRY   
    print 'Start - Begin Try' 

    INSERT INTO [FlightOrderUploadFailedLog]
           (EvtTyp) 
           VALUES ('max size of EvtType is only varchar(15) so this should cause truncation') 
    print 'after insert #2 ' 
    print 'Message=' + IsNull(error_message(),'null') 
    print 'State=' + IsNull(convert(varchar(4),error_state()),'null') 
    print 'ErrorNumber=' + IsNull(convert(varchar(8),error_number()),'null') 


    print 'The End' 

END TRY
BEGIN CATCH
    print 'Catch'
    print 'Message=' + error_message() 
    print 'State=' + convert(varchar(4),error_state()) 
    print 'ErrorNumber=' + convert(varchar(8),error_number()) 
    return   -- error has been theoretically handled by writing it to a database 

END CATCH 

END
GO

结果：

Start
Msg 8152, Level 16, State 4, Procedure TestErrorHandling2, Line 21
String or binary data would be truncated.
The statement has been terminated.
after insert #1
Message=null
State=null
ErrorNumber=null
Start - Begin Try

(0 row(s) affected)
Catch
Message=String or binary data would be truncated.
State=4
ErrorNumber=8152
-6

Answer 1

好吧，让我尽我所能。

“最佳实践” - 我讨厌这句话，因为10次中有9次这纯粹是主观的，因为有人在某处阅读。

所以我的主观答案是看到你可以嵌套try / catch并放一个try/catch within the catch block - 那么我认为把一个try / catch放在catch中是很好的错误处理 - 如果你拥有的可以抛出一个错误并且非常严重，你希望自己处理它。

所以IMO - 最佳做法是肯定的，使用try try / catch来更好地处理错误。

其次 - 你的“捕获”没有爆炸的原因是截断错误不是批量终止错误。它的错误级别不够高，因此将执行后续语句。只需用打印声明试一试：

PRINT 'something'
--do your insert here
PRINT 'somethingelse'

然后你会看到你应该得到两个印刷语句。如果要将ANSI_WARNINGS更改为OFF，甚至可以抑制截断错误。不是我会推荐，但是......：）

如果你的catch中有try / catch，那么应该捕获截断错误，因为严重性足以触发catch。

T-SQL是否在“BEGIN CATCH”块中完全关闭了错误处理？

1 个答案: