Question

我在使用XSLT检查节点是否存在时遇到了一些麻烦，如果没有将它们添加到文档中。这是我的情况：

输入

<Message>
  <a>123</a>
  <c>456</c>
  <d>789</d>
</Message>

所需的输出

<MsgHead>
  <Document>
    <Message>
     <a>123</a>
     <b>-1</b>
     <c>456</c>
     <d>789</d>
    </Message>
  <Document>
</MsgHead>

我还获得了以下带有“默认值”的静态文件

默认值

<DefaultNodes>
  <a>-1</a>
  <b>-1</b>
  <c>-1</c>
  <d>-1</d>
 </DefaultNodes>

输入文件具有不同数量的节点，我需要使用缺少的默认节点“完成”它们。节点名称显然不是a，b，c等，而是大约700个具有不同默认值的不同节点。

到目前为止，这是我的尝试 我的XSLT

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">    
    <xsl:template match="/">
        <MsgHead>
            <Document>
                <Message>
                    <xsl:apply-templates></xsl:apply-templates>
                </Message>
            </Document>
        </MsgHead>
    </xsl:template>

    <xsl:template match="Message">
        <xsl:copy-of select="node()"/>
        <xsl:for-each select="document('default-nodes.xml')/DefaultNodes/*">
            <xsl:choose>
                <xsl:when test="//*[local-name(current())]"> <!-- This is the line giving me trouble -->
                    <!--Node already present, do nothing-->                    
                </xsl:when>
                <xsl:otherwise>
                    <!--Node not in input, add from the defaults file -->
                    <xsl:copy-of select="self::node()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

这几乎正常，但似乎无法找到节点是否存在。我正在使用的当前测试（// * [local-name（current（））]）无论如何都会返回true。有人对我如何解决这个问题有任何建议吗？

谢谢！

Answer 1

我正在使用的当前测试（// * [local-name（current（））]）似乎无论什么都返回

是的，因为（在您测试它的上下文中）该测试意味着“如果此模板的当前节点的本地名称非空，则选择整个default-nodes.xml文档中的所有元素，否则根本不做任何选择“。

我假设default-nodes.xml定义了您希望结果元素出现的顺序，DefaultNodes下的所有元素都有不同的名称。在那种情况下，如何：

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">    

    <!-- store a reference to the root of the main input tree  -->
    <xsl:variable name="root" select="/" />

    <xsl:template match="/">
        <MsgHead>
            <Document>
                <Message>
                    <xsl:apply-templates select="document('default-nodes.xml')/DefaultNodes/*"/>
                </Message>
            </Document>
        </MsgHead>
    </xsl:template>

    <xsl:template match="DefaultNodes/*">
        <!-- look for a matching element in the main input tree -->
        <xsl:variable name="sourceNode" select="$root/Message/*[name() = name(current())]" />
        <xsl:choose>
            <!-- if such a node exists, copy it -->
            <xsl:when test="$sourceNode">
                <xsl:copy-of select="$sourceNode" />
            </xsl:when>
            <!-- else copy the default one -->
            <xsl:otherwise>
                <xsl:copy-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

这里我将模板应用于默认元素，而不是输入元素。

请注意使用变量$root来保存对主输入树的引用。在DefaultNodes/*模板中，当前节点来自default-nodes.xml，因此在该上下文中/表示该文件的根，而不是主输入的根树。

Answer 2

可能这不是最简洁的解决方案，但它有效。

顺便说一句，local-name返回一个没有命名空间的名称（即冒号后的部分）。万一你不知道这件事。

<强>样式表

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
    <MsgHead>
        <Document>
            <Message>
                <xsl:apply-templates/>
            </Message>
        </Document>
    </MsgHead>
</xsl:template>

<xsl:template match="Message">
    <xsl:variable name="msg" select="."/>
    <xsl:for-each select="document('default-nodes.xml')/DefaultNodes/*">
        <xsl:choose>
           <xsl:when test="$msg/*/name()=current()/name()">
              <xsl:copy-of select="$msg/*[name()=current()/name()]"/>
           </xsl:when>
           <xsl:otherwise>
              <xsl:copy-of select="."/>
           </xsl:otherwise>
        </xsl:choose>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

<强>输出

<?xml version="1.0" encoding="UTF-8"?>
<MsgHead>
 <Document>
  <Message>
     <a>123</a>
     <b>-1</b>
     <c>456</c>
     <d>789</d>
  </Message>
 </Document>
</MsgHead>

Answer 3

此XSLT 1.0样式表...

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:esl="urn:schemas-microsoft-com:xslt" 
  exclude-result-prefixes="xsl esl" >
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />    

<xsl:key name="kByName" match="*" use="local-name()" />  

<xsl:variable name="DefaultNodes">
 <DefaultNodes>
  <a>-1</a>
  <b>-1</b>
  <c>-1</c>
  <d>-1</d>
 </DefaultNodes>  
</xsl:variable> 

<xsl:template match="Message">
 <MsgHead>
  <Document>
   <xsl:copy> 
     <xsl:variable name="union">
       <xsl:apply-templates select="* | esl:node-set($DefaultNodes)/DefaultNodes/*[local-name()]"/>
     </xsl:variable>
     <xsl:copy-of select="esl:node-set($union)/*[generate-id() = generate-id(key('kByName',local-name())[1])]" />
   </xsl:copy> 
  </Document> 
 </MsgHead>
</xsl:template>

<xsl:template match="@*|node()">
  <xsl:copy> 
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy> 
</xsl:template>    

</xsl:stylesheet>

...应用于此输入文档时...

<Message>
  <a>123</a>
  <c>456</c>
  <d>789</d>
</Message>

...收益......

<MsgHead>
  <Document>
    <Message>
      <a>123</a>
      <c>456</c>
      <d>789</d>
      <b>-1</b>
    </Message>
  </Document>
</MsgHead>

注意：根据需要将esl名称空间更改为http://exslt.org/common，具体取决于您的XSLT处理器。

如果XSLT不存在，则添加新节点

3 个答案: