Question

我是哈斯克尔的新手，我读完并消化Learn You A Haskell For Great Good，沿途尝试了几件事。对于我的第一个项目，我想尝试经典：FizzBuzz。所以我想出了以下代码：

import System.IO

fizzBuzz :: (Integral a) => a -> String
fizzBuzz num
    | fizz && buzz = "FizzBuzz"
    | fizz = "Fizz"
    | buzz = "Buzz"
    | otherwise = show num
    where fizz = num `mod` 3 == 0
          buzz = num `mod` 5 == 0

main = print $ map fizzBuzz [1..100]

工作得很好，除了我有一个很难读的相当密集的列表。所以我尝试了这个主要功能：

main = map putStrLn $ map fizzBuzz [1..100]

这给了我错误Couldn't match expected type 'IO t' against inferred type '[IO ()]'。我尝试了六件事，似乎没有任何帮助。做我正在做的事情的正确方法是什么？

Answer 1

map :: (a -> b) -> [a] -> [b]
putStrLn :: Show a => a -> IO ()
map putStrLn :: Show a => [a] -> [IO ()]

您有一个IO ()行动清单。

main :: IO ()

您需要将它们加入到单个IO ()操作中。

您要做的是在sequence / sequence_中执行每项IO ()次操作：

sequence :: Monad m => [m a] -> m [a]
sequence_ :: Monad m => [m a] -> m ()

为方便起见，mapM / mapM_会将一个函数映射到列表中，并对生成的monadic结果进行排序。

mapM :: Monad m => (a -> m b) -> [a] -> m [b]
mapM_ :: Monad m => (a -> m b) -> [a] -> m ()

所以你的固定代码看起来像这样：

main = mapM_ putStrLn $ map fizzBuzz [1..100]

虽然我可能会这样写：

main = mapM_ (putStrLn . fizzBuzz) [1..100]

甚至这个：

main = putStr $ unlines $ map fizzBuzz [1..100]

让我们自己编写sequence。我们想要它做什么？

sequence [] = return []
sequence (m:ms) = do
    x <- m
    xs <- sequence ms
    return $ x:xs

如果列表中没有任何内容，请返回（注入monad）一个空的结果列表。
否则，在monad中，
- 绑定（对于IO monad，这意味着执行）第一个结果。
- sequence列表的其余部分;绑定结果列表。
- 返回第一个结果和其他结果列表的缺点。

GHC的图书馆使用更像foldr (liftM2 (:)) (return [])的东西，但这对新手来说更难解释;现在，请接受我的说法，即他们是等同的。

sequence_更容易，因为它不会忘记跟踪结果。 GHC的库将其实现为sequence_ ms = foldr (>>) (return ()) ms。我们只是扩展foldr：

的定义

  sequence [a, b, c, d]
= foldr (>>) (return ()) [a, b, c, d]
= a >> (b >> (c >> (d >> return ())))

换句话说，“执行a，弃掉结果;执行b;丢弃结果，......最后，返回()”。

mapM  f xs = sequence  $ map f xs
mapM_ f xs = sequence_ $ map f xs

另一方面，您甚至不需要使用备用unlines解决方案来了解monad。

unlines做什么？好吧，lines "a\nb\nc\nd\n" = ["a", "b", "c", "d"]，当然也是unlines ["a", "b", "c", "d"] = "a\nb\nc\nd\n"。

unlines $ map fizzBuzz [1..100] = unlines ["1", "2", "Fizz", ..] = "1\n2\nFizz\n..."然后关闭putStr。由于Haskell懒惰的魔力，完整的字符串永远不需要在内存中构建，所以这将很高兴地转到[1..1000000]或更高版本：）

Haskell - 漂亮打印列表的问题

1 个答案: