Question

我需要一个批处理文件或实用程序，它能够找到不再需要的任何“未压缩的存档文件夹”，现在可以删除，因为原始存档文件仍然存在。

关键是“未压缩文件夹”和“原始存档文件”总是具有相同的名称，但存档文件的文件扩展名除外。我不想自动删除任何东西;我只想创建一个可以手动签出的文件夹列表。所以序列将是一个4步过程：

1）使用通配符搜索所有存档文件，例如* .zip，* .rar，* .iso 2）创建找到的所有文件名列表 - 减去文件扩展名 3）使用在步骤2中创建的列表搜索具有这些名称的任何文件夹 4）使用在步骤3中找到的任何文件夹创建一个文本文件。

我尝试修改我在这些帖子中找到的批处理文件，但它没有用，我想从头开始。任何帮助将不胜感激。

由于

Answer 1

好的，我会一步一步地做到这一点：

第1步：

set dir="C:\...[path to root directory]" 
where /r %dir% *.zip *.iso *.rar >> log.txt

注意如果使用Windows 7，where实用程序应该在您的计算机上。

第2步：

ren log.txt log.tmp
for /f "delims=." %%a in (log.tmp) do (Echo %%a >> log.txt)
del log.tmp

以上代码不会处理带有句点的文件名

第3步：

for /f "tokens=*" %%a in (log.txt) do (
where /r %dir% %%a* >> files.txt
)

如果不是100％确定是否有效，请告诉我它是否有效。

第4步：

Rem This code will handle file paths to directories
Ren files.txt files.tmp
for /f "tokens=*" %%a in (files.tmp) do (
Echo %%~pa >> files.txt
)
del files.tmp

Rem The below code will ged rid of repeated direcotries
ren files.txt files.tmp
Echo. > files.txt

setlocal enabledelayedexpansion
for /f "tokens=*" %%a in (files.tmp) do (
set var=1
for /f "tokens=*" %%b in (files.txt) do (
if "%%~a" equ "%%~b" set var=0
)
if !var!==1 Echo %%a >> files.txt
)
del files.tmp

我相信应该有效。当然我没有对此进行测试，但是使用@Echo on和每个部分之间的暂停命令（或作为单独的批处理文件）运行所有这些，这样如果确实发生了错误，我可以尝试帮助你。

希望这很有帮助，Mona。

Answer 2

@echo off

    setlocal enableextensions

    set "rootDir=d:\_data_"
    set "fileList=%~dp0\%~n0.files.list"
    set "folderList=%~dp0\%~n0.folders.list"

    rem generate list of compressed files names
    break > "%fileList%"
    for /F "tokens=*" %%f in ('where /r "%rootDir%" *.zip *.rar *.iso *.7z 2^>nul') do (
        >> "%fileList%" echo %%~nf
    )

    rem check compressed file list against directory list
    break > "%folderList%"
    for /F "tokens=*" %%f in ('dir "%rootDir%" /s /b /ad ^| findstr /e /g:"%fileList%" ') do (
        >> "%folderList%" echo %%f
    )

    type "%folderList%"

    endlocal

需要一个可以根据文件名查找文件夹的批处理文件

2 个答案:

第1步：

第2步：

第3步：

第4步：