在gnuplot xaxis上混合日期和时间

Question

我想在x轴上绘制一天中的小时数，但是当一天从一天到下一天滚动时打印日期。所以x轴可能如下所示：

11/02 04:00 08:00 12:00 16:00 20:00 11/03 04:00 08:00 ...

在gnuplot中有没有明智的方法呢？

FWIW，我的文件目前看起来像这样：

set xdata time
set timefmt "%Y-%m-%d|%H:%M:%S"
plot '-' using 1:2 with lines linewidth 1 linecolor rgb "#FF0000"
2013-11-02|00:00:48 123.0
2013-11-02|00:00:55 124.0
2013-11-02|00:01:06 121.0
2013-11-02:00:01:17 123.0
...
2013-11-04|23:59:41 241.0
2013-11-04|23:59:52 241.0

Answer 1

这是一个艰难的，让我思考一下。以下是如何做到这一点：

您需要将x轴的格式设置为%H:%M，然后将00:00替换为日期，类似于完成in this answer。

然后主要工作是提取中午的时间戳。我使用stats命令（至少需要4.6.0版本），但因为它不支持时间数据，所以你必须使用strptime类似的方法：

fmt = "%Y-%m-%d|%H:%M:%S"
stats 'file.txt' using (strptime(fmt, stringcolumn(1))) nooutput
t = int(STATS_min)
t_start = t - tm_hour(t)*60*60 - tm_min(t)*60 - tm_sec(t)
num_days = 2 + (int(STATS_max) - t)/(24*60*60)

set xdata time
set timefmt fmt
set xtics 4*60*60
set for [i=1:num_days] xtics add (strftime('%m/%d', t_start+(i-1)*24*60*60) t_start+(i-1)*24*60*60)
set format x '%H:%M'
plot 'file.txt' using 1:2 with lines

我将num_days增加2以说明可能会自动将x范围扩展到下一个抽搐。

您的数据的结果是（使用4.6.4）：

Answer 2

以下是带有xticlabels的版本：

$data <<EOD
2013-11-02|00:00:48 123.0
2013-11-02|00:00:55 124.0
2013-11-02|00:01:06 121.0
2013-11-02|00:01:17 123.0
2013-11-04|23:59:41 241.0
2013-11-04|23:59:52 241.0
EOD

set xdata time
set timefmt "%Y-%m-%d|%H:%M:%S"

plot $data using 1:2 w l # plot to get GPVAL_X_MIN GPVAL_X_MAX

t = GPVAL_X_MIN
t_start = t - tm_hour(t)*60*60 - tm_min(t)*60 - tm_sec(t)
num_days = 1 + (GPVAL_X_MAX-GPVAL_X_MIN)/(24*60*60)

replot [i=0:6*num_days:1] '+' us (t=t_start+i*24*60*60/6, strftime('%Y-%m-%d|%H:%M:%S', t)):(NaN):xtic(strftime(int(i)%6?'%H:%M':'%m-%d',t)) t ""

因此使用int(i)%6?'%H:%M':'%m-%d'选择了格式。

这是受gnuplot: set link and x2tics in interactive mode启发的。