Question

我只是想知道是否有办法在几秒钟内通过VBScript将mp3文件的长度变为变量。

Answer 1

使用Windows Media Player控件库是另一种方式。在使用之前，请确保路径正确。

Function MediaDuration(path)
    With CreateObject("Wmplayer.OCX")
        .settings.mute = True
        .url = path
        Do While Not .playState = 3 'wmppsPlaying
            WScript.Sleep 50
        Loop
        MediaDuration = Round(.currentMedia.duration) 'in seconds
        'MediaDuration = .currentMedia.durationString 'in hh:mm:ss format
        .Close 
    End With
End Function

WScript.Echo MediaDuration("C:\media\song.mp3")

Answer 2

（从my answer改编为关于JScript的类似问题。）

您可以使用Windows Shell GetDetailsOf对象的Folder方法获取音频文件长度。此技术支持所有音频文件类型，其本地化的Windows资源管理器可以读取和显示元数据。

但请注意，不同Windows版本的Length属性索引不同：Windows XP / 2003上为21，Windows Vista上为27。有关详细信息，请参阅this page和this my answer。您需要在脚本中考虑这一点。

示例代码：

Const LENGTH = 27 ' Windows Vista+
' Const LENGTH = 21 ' Windows XP

Dim oShell  : Set oShell  = CreateObject("Shell.Application")
Dim oFolder : Set oFolder = oShell.Namespace("C:\Music")
Dim oFile   : Set oFile   = oFolder.ParseName("Track.mp3")

Dim strLength : strLength = oFolder.GetDetailsOf(oFile, LENGTH)

WScript.Echo strLength

示例输出：

0点05分18秒

Answer 3

Set objShell = CreateObject("Shell.Application")
Set Ag=Wscript.Arguments
set WshShell = WScript.CreateObject("WScript.Shell")

WshShell.RegWrite "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\" & Wscript.ScriptName & "\", Chr(34) & Wscript.ScriptFullName & Chr(34) 
WshShell.RegWrite "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\" & Left(Wscript.ScriptName, Len(Wscript.ScriptName)-3) & "exe" & "\", Chr(34) & Wscript.ScriptFullName & Chr(34) 

Set Fldr=objShell.NameSpace(Ag(0))

Set FldrItems=Fldr.Items
Set fso = CreateObject("Scripting.FileSystemObject")


Set DeskFldr=objShell.Namespace(16)
FName=fso.buildpath(DeskFldr.self.path, "Folder Property List.txt")


Set ts = fso.OpenTextFile(FName, 8, vbtrue)



For x = 0 to 50
    t1 = t1 & Fldr.GetDetailsOf(vbnull, x) & " (Shell)" & vbtab
Next
ts.write FLDR.self.path &vbcrlf
ts.Write T1 & vbcrlf
T1=""


For Each FldrItem in FldrItems
    For x = 0 to 50
        t1 = t1 & Fldr.GetDetailsOf(FldrItem, x) & vbtab
    Next
    t1=t1 & vbcrlf
    ts.Write T1
    T1=""
Next

'msgbox FName & "has a tab delimited list of all properties"

如果您在上面放置一个文件夹，它将生成该文件夹中文件的所有shell属性的列表。我没有任何mp3文件。这将取决于您安装的软件将会发生什么。 Wma文件将持续时间留空。从Windows版本到版本，属性发生了巨大变化。

第一个循环获取可用的属性（通过为folderitem传递null），第二个循环获取每个folderitem的属性。

在VBScript中读取音乐文件长度

3 个答案: