Question

我需要一个批处理文件，应该在PC上搜索今天发布的所有名为“example.ini”的文件，并替换一个字符串，该字符串将位于“example.ini”的第二行，它应该替换

SERVER_IP=111.111.111.111与另一台服务器ip SERVER_IP=222.222.222.222

这怎么可能？

Answer 1

在一些示例文件上测试它。

它会更改example.ini和包含c:\的子目录中的SERVER_IP=212.83.63.108个文件，并将其更改为SERVER_IP=222.22.22.222

它使用来自 - https://www.dropbox.com/s/qidqwztmetbvklt/repl.bat

的名为repl.bat的帮助程序批处理文件

将repl.bat放在与批处理文件相同的文件夹中。

@echo off
for /r c:\ %%a in (example.ini) do (
find "SERVER_IP=212.83.63.108" <"%%a" >nul && (
    echo processing "%%a"
    type "%%a"|repl "SERVER_IP=212\.83\.63\.108" "SERVER_IP=222.22.22.222" >"%%a.tmp"
    move /y "%%a.tmp" "%%a" >nul
    )
)

Answer 2

在32位窗口上，Edlin（dos编辑器）可用。

12 
New text
e

是一个edlin脚本，在文件的第12行写入“新文本”。型

edlin

然后

使用

edlin c:\folder\filename.ext < edlin.script

您必须使用短文件名。文件必须低于64K行。

Answer 3

在今天在驱动器c的任何子目录中创建的名为example.ini的第二行文件中，通过String2更改String1：

@echo off
    setlocal enableextensions enabledelayedexpansion

    rem Arguments:
    rem     %1 = search string
    rem     %2 = replace string
    rem     [ %3 = file in where to replace ] 
    rem            this parameters is internally used by the 
    rem            batch file while processing

    rem chech for parameters
    if "%~2"=="" goto :EOF

    rem retrieve parameters
    set "_search=%~1"
    set "_replace=%~2"

    rem check if asked to replace in a file 
    rem this will be done recursively from this same batch
    if not "%~3"=="" (
        set "_file=%~3"
        goto doFileReplace
    )

    forfiles /P C:\ /S /M example.ini /D +0 /C "cmd /c if @isdir==FALSE findstr /c:\"%_search%\" \"@path\" >nul && %~dpnx0 \"%_search%\" \"%_replace%\" @path "

    goto :EOF

:doFileReplace
    echo "%_file%"
    set "_tempFile=%temp%\%~nx0.tmp"
    break > "%_tempFile%"
    (for /F "tokens=1,* delims=:" %%l in ('findstr /n /r "." "%_file%"') do (
        if %%l EQU  2 (
            set "_text=%%m"
            echo !_text:%_search%=%_replace%!
        ) else (
            echo %%m
        )
    ))>>"%_tempFile%"

    copy /Y "%_tempFile%" "%_file%" >nul 
    goto :EOF

批处理文件以搜索和替换字符串

3 个答案: