在您的代码中

Question

当从XML拉到XSLT 1.0时，一直试图将文本格式化为DD-MM-YYYY，因为我知道在使用xs：date时必须在XSD / XML中将其设置为YYYY-MM-DD。我用过的东西。

以下是我正在处理的代码，有关如何显示此代码的任何建议吗？

XML

<?xml version="1.0" encoding="ISO-8859-1"?>
<events xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
        xsi:noNamespaceSchemaLocation="events.xsd">
  <venue id="01" 
         vtitle="ExCeL Exhibition Centre" 
         location="London" 
         telephone="0844 448 7600">
   <event name="Doctor Who 50th Celebration" date="2013-10-22">
    <image>images/doctor50.jpg</image><attribute>Doctor Who Event</attribute>
    <description>A 50th Anniversary musical bonanza for Doctor Who.</description>
    <ticket_price type="adult" status="available">&#163;25.00</ticket_price>
    <ticket_price type="child" status="none">&#163;11.00</ticket_price>
    <ticket_price type="junior" status="available">&#163;0.00</ticket_price>
    <email>info@roundhouselondon.com</email>
</event>
</venue>

XSD

<xs:attribute name="date" type="xs:date"/>

XSLT

<xsl:element name="date"><xsl:value-of select="@date"/></xsl:element>

HTML

<date>2013-10-22</date>

Answer 1

另一种以dd / mm / yyyy形式生成日期的简单解决方案

<xsl:value-of select="
  concat(substring(@date, 9, 2), 
         '/', 
         substring(@date, 6, 2),
         '/', 
         substring(@date, 1, 4))"/>

Answer 2

我会使用@Stormtroopr提供的1.0和2.0的不同解决方案。

在2.0中使用

format-date(xs:date($date), '[D01]-[M01]-[Y0001]')

在1.0中使用

concat(substring(., 9, 2), 
         '-', 
         substring(., 6, 2), 
         '-', 
         substring(., 1, 4))

为了将来参考，请告诉我们您使用的是哪个版本的XSLT。 1.0和2.0都是常用的，解决方案通常不同。

Answer 3

我正在将它用于SharePoint，我像这样解决了它

<xsl:value-of select=" ddwrt:FormatDate(/dsQueryResponse/Rows/Row/@Date,3,1)"/>

Answer 4

在XSLT 2.0中，您可以使用tokenize分割字符串，然后使用xsl:for-each和xsl:sort来反转它。（我现在没有XSLT2.0引擎，但这非常接近你所需要的。）

<xsl:for-each select="tokenize(@date,'-'">
    <xsl:sort select="position()" data-type="number" order="descending"/>
    <xsl:value-of select="."/>
</xsl:for-each>

在XSLT 1.0中，您可以使用...递归！

这是它的关键，这需要一个日期，然后在第一个连字符（-）之前和之后搜索字符串。通常情况下，在处理substring-before之后你会subtring-after来保留订单，但在这里我们将它们切换为最终反转输出。

<xsl:template name="reverse-date">
    <xsl:param name="text" select="."/>
    <xsl:choose>
        <xsl:when test="contains($text, '-')">
            <xsl:call-template name="reverse-date">
                <xsl:with-param name="text" select="substring-after($text, '-')"/>
            </xsl:call-template>
            <xsl:text>-</xsl:text>
            <xsl:value-of select="substring-before($text, '-')" />
        </xsl:when>
        <xsl:otherwise>
           <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

以下是完整的模板，它将根据您的上述XML文档反转您的日期。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
  <xsl:apply-templates select="//event"/>
</xsl:template>

<xsl:template match="event">
  <xsl:element name="date">
    <!--
         ** Call this template when you want to reverse the date **
    -->
    <xsl:call-template name="reverse-date">
     <xsl:with-param name="text" select="@date" />
    </xsl:call-template>
  </xsl:element>
</xsl:template>

<xsl:template name="reverse-date">
    <xsl:param name="text" select="."/>
    <xsl:choose>
        <xsl:when test="contains($text, '-')">
           <xsl:value-of select="substring-before($text, '-')" />
            <xsl:text>-</xsl:text>
            <xsl:call-template name="reverse-date">
                <xsl:with-param name="text" select="substring-after($text, '-')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
           <xsl:value-of select="normalize-space($text)"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

在您的代码中

你需要改变这个：

<xsl:element name="date"><xsl:value-of select="@date"/></xsl:element>

对此：

<xsl:element name="date">
  <xsl:call-template name="reverse-date">
    <xsl:with-param name="text" select="@date" />
  </xsl:call-template>
</xsl:element>

Answer 5

这段代码可能有帮助：

    for children in child:
        if children.tag  == "dateTime":
            list_dateTime = [children.text] 
            lista=list_dateTime             
            simbolo=('/')
            simboloh=(':')            
            Lis=str(lista)
            dd=Lis[2:4]
            mm=Lis[4:6]
            yy=Lis[6:10]
            hh=Lis[10:12]
            mms=Lis[12:14]
            data=dd + simbolo + mm+  simbolo + yy+  simbolo +hh+ simboloh + mms
        if children.tag == "field":
            for subchildren in children:
                if subchildren.tag == "id":
                    list_id = [subchildren.text]
                if subchildren.tag =="value":
                    list_value = [subchildren.text]
                    arquivo.writelines('\n')
                    arquivo.writelines(list_period)
                    arquivo.writelines(',')
                    arquivo.writelines(data)
                    arquivo.writelines(',')
                    arquivo.writelines(list_id)
                    arquivo.writelines(',')
                    arquivo.writelines(list_value)

在XSLT / XML中将日期显示为DD-MM-YYYY

5 个答案:

在您的代码中