Question

我正在尝试制作一个excel宏，它将在Excel中提供以下功能：

=SQL("SELECT heading_1 FROM Table1 WHERE heading_2='foo'")

允许我使用SQL查询在我的工作簿表中搜索（甚至可能插入）数据。

这是我到目前为止所做的：

Sub SQL()

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon

strSQL = "SELECT * FROM [Sheet1$A1:G3]"

rs.Open strSQL, cn

Debug.Print rs.GetString

End Sub

我的脚本就像一个带有硬编码范围的魅力，例如上面代码段中的那个。它也适用于静态命名范围。

但是，对于我来说，它不适用于动态命名范围或TABLE NAMES。

我找到的答案最接近的是这个遭受同样痛苦的人： http://www.ozgrid.com/forum/showthread.php?t=72973

帮助任何人？

修改

到目前为止，我已经熟了这个，然后我可以在SQL查询中使用结果名称。限制是我需要知道表格在哪张纸上。我们能为此做些什么吗？

Function getAddress()

    myAddress = Replace(Sheets("Sheet1").Range("Table1").address, "$", "")
    myAddress = "[Sheet1$" & myAddress & "]"

    getAddress = myAddress

End Function

谢谢！

Answer 1

您可以做的一件事是获取动态命名范围的地址，并将其用作SQL字符串中的输入。类似的东西：

Sheets("shtName").range("namedRangeName").Address

会吐出一个地址字符串，例如$A$1:$A$8

编辑：

正如我在下面的评论中所说，您可以动态获取完整地址（包括工作表名称），并直接使用它或解析工作表名称以供日后使用：

ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal

这导致像=Sheet1!$C$1:$C$4这样的字符串。因此，对于上面的代码示例，您的SQL语句可能是

strRangeAddress = Mid(ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal,2)

strSQL = "SELECT * FROM [strRangeAddress]"

Answer 2

Public Function GetRange(ByVal sListName As String) As String

Dim oListObject As ListObject
Dim wb As Workbook
Dim ws As Worksheet

Set wb = ThisWorkbook

For Each ws In wb.Sheets
    For Each oListObject In ws.ListObjects
        If oListObject.Name = sListName Then
            GetRange = "[" & ws.Name & "$" & Replace(oListObject.Range.Address, "$", "") & "]"
        Exit Function
        End If
    Next oListObject
Next ws


End Function

在你的SQL中使用它就像这样

sSQL = "Select * from " & GetRange("NameOfTable") & ""

Answer 3

以Joan-Diego Rodriguez为例，使用Jordi的方法和Jacek Kotowski的一些代码 - 此函数将活动工作簿的任何表名转换为SQL查询的可用地址。

MikeL注意：添加“[#All]”包括避免报告问题的标题。

Function getAddress(byVal sTableName as String) as String 

    With Range(sTableName & "[#All]")
        getAddress= "[" & .Parent.Name & "$" & .Address(False, False) & "]"
    End With

End Function

Answer 4

我是初学者，修补其他人的代码，所以请宽容并进一步纠正我的错误。我尝试了你的代码并使用了VBA帮助。以下内容与我合作：

Function currAddressTest(dataRangeTest As Range) As String

    currAddressTest = ActiveSheet.Name & "$" & dataRangeTest.Address(False, False)

End Function

当我为我的函数选择数据源参数时，它将变为Sheet1 $ A1：G3格式。如果excel将其更改为我的公式中的Table1 [＃All]引用，则该函数仍然可以正常工作

然后我在你的函数中使用它（尝试播放并添加另一个参数以注入WHERE ...

Function SQL(dataRange As Range, CritA As String)

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim currAddress As String



currAddress = ActiveSheet.Name & "$" & dataRange.Address(False, False)

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon


strSQL = "SELECT * FROM [" & currAddress & "]" & _
         "WHERE [A] =  '" & CritA & "'  " & _
         "ORDER BY 1 ASC"

rs.Open strSQL, cn

SQL = rs.GetString

End Function

希望你的功能进一步发展，我发现它非常有用。祝你有愉快的一天！

Answer 5

回答关于获取表格所在表格名称的问题的第二部分：

Dim name as String

name = Range("Table1").Worksheet.Name

编辑：

为了使事情更清楚：有人建议在Sheet对象上使用Range。在这种情况下，你不需要;桌子所在的范围可以使用表格的名称获得;这个名字可以在整本书中找到。所以，单独调用Range效果很好。

Answer 6

您最近对此进行了调查，并且在excel

中引用了命名表（列表对象）时遇到了问题

如果你加上后缀＆＃39; $＆＃39;在桌子上的名字一切都在世界各地

Sub testSQL()

    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset

    ' Declare variables
    strFile = ThisWorkbook.FullName

    ' construct connection string
    strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
    & ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

    ' create connection and recordset objects
    Set cn = CreateObject("ADODB.Connection")
    Set rs = CreateObject("ADODB.Recordset")

    ' open connection
    cn.Open strCon

    ' construct SQL query
    strSQL = "SELECT * FROM [TableName$] where [ColumnHeader] = 'wibble';"

    ' execute SQL query
    rs.Open strSQL, cn

    Debug.Print rs.GetString

    ' close connection
    rs.Close
    cn.Close
    Set rs = Nothing
    Set cn = Nothing
End Sub

Answer 7

找到了这个，它对我有用。

strSQL = "SELECT * FROM DataTable"

'DataTable是命名范围

How can I run SQL statements on a named range within an excel sheet?

使用VBA宏在工作簿中的Excel表上执行SQL查询

7 个答案: