Question

我需要处理ORA-01400 error（不能使用异常句柄将NULL插入（“SCHEMA”。“TABLE_NAME”。“COLUMN_NAME”））。

ORACLE预定义了一些例外（例如ACCESS_INTO_NULL，ZERO_DIVIDE等），但显然没有为ORA-01400错误定义异常，我该如何处理这个特定的错误代码？

我需要这样的东西（接受其他建议）。

....
 ...     
 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);
 COMMIT;
   EXCEPTION
     WHEN NULL_VALUES THEN /* i don't know this value , exist?*/
       Do_MyStuff();
     WHEN OTHERS THEN
       raise_application_error(SQLCODE,MY_OWN_FORMAT_EXCEPTION(SQLCODE,SQLERRM),TRUE); 
    END;

Answer 1

预定义的PL / SQL异常是Oracle的特殊。你真的不能搞砸那些。如果您想拥有一组自己的预定义异常，则不能像标准的那样“全局”声明它们。而是创建一个例外包，其中包含所有异常声明，并在应用程序代码中使用它。

示例：

CREATE OR REPLACE PACKAGE my_exceptions
AS
  insert_null_into_notnull EXCEPTION;
  PRAGMA EXCEPTION_INIT(insert_null_into_notnull, -1400);

  update_null_to_notnull EXCEPTION;
  PRAGMA EXCEPTION_INIT(update_null_to_notnull, -1407);
END my_exceptions;
/

现在使用包

中定义的异常

CREATE OR REPLACE PROCEDURE use_an_exception AS
BEGIN
  -- application specific code ...
  NULL;
EXCEPTION
  WHEN my_exceptions.insert_null_into_notnull THEN
     -- application specific handling for ORA-01400: cannot insert NULL into (%s)
     RAISE;
END;
/

来源：http://www.orafaq.com/wiki/Exception

Answer 2

您可以通过以下代码处理异常：

....
 ...
 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);   
 COMMIT;   
   EXCEPTION   
     WHEN OTHERS THEN   
       IF SQLCODE = -1400 THEN
         Do_MyStuff();
       ELSE
         raise_application_error(SQLCODE,MY_OWN_FORMAT_EXCEPTION(SQLCODE,SQLERRM),TRUE);
       END IF;
    END;

Answer 3

您可以定义自己的异常，例如变量（它们将与其他变量具有相同的范围，因此您可以定义包异常等等）：

SQL> DECLARE
  2     NULL_VALUES EXCEPTION;
  3     PRAGMA EXCEPTION_INIT(NULL_VALUES, -1400);
  4  BEGIN
  5     INSERT INTO t VALUES (NULL);
  6  EXCEPTION
  7     WHEN null_values THEN
  8        dbms_output.put_line('null value not authorized');
  9  END;
 10  /

null value not authorized

PL/SQL procedure successfully completed

Answer 4

 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);
 COMMIT;  

      EXCEPTION
         WHEN NULL_VALUES /* i don't know this value , exist?*/
           emesg := SQLERRM;
           dbms_output.put_line(emesg); 
         WHEN OTHERS THEN
           emesg := SQLERRM;
           dbms_output.put_line(emesg);
         END;

SQLERRM显示sql错误消息

http://www.psoug.org/reference/exception_handling.html

处理ORACLE例外

4 个答案: