Question

请，

我需要知道开发人员何时提交项目，以便其他开发人员可以收到有关他们的版本需要更新的通知。

有一些命令行可以做到这一点吗？

Answer 1

您可以使用一个名为CommitMonitor的简单工具。它位于托盘中并通知新提交。不过这只是Windows版本。

http://stefanstools.sourceforge.net/CommitMonitor.html

通常，提交不需要其他人立即更新。通常，开发人员自己决定何时更新，因为工作中间的更新会让你退缩（即你必须进行重建，修复正在处理的代码中的合并冲突等。）

Answer 2

我们通过post-commit.cmd中的post-commit钩子通知tolist.txt中的人员：


set repo=%1
set rev=%2
set svnlook="svnlook.exe"
if exist "%repo%\hooks\blat" set blat="%repo%\hooks\blat\blat.exe"

:ok

if [%blat%]==[] goto :exitzero

set tmpfile=c:\temp\blat%RANDOM%

:: Build subject line
for /f "tokens=1,2 delims=/" %%i in ('svnlook dirs-changed %repo% -r %rev%') do set lev1=%%i&&set lev2=%%j
for /f %%i in ('svnlook author %repo% -r %rev%') do set author=%%i
set subject="%author% committed to %lev1%/%lev2%"

:: Build email text
echo>>%tmpfile% Author, Commit date, Message length, and Message
%svnlook% info %repo% -r %rev% >>%tmpfile%
echo.>>%tmpfile%
echo>>%tmpfile% List of files changed:
%svnlook% changed %repo% -r %rev% >>%tmpfile%

set tolist="%repo%\hooks\tolist.txt"

%blat% -install smtpaddress.company.com myuserid@company.com
%blat% %tmpfile% -tf %tolist% -from Subversion -replyto myuserid@company.com -subject %subject%
del %tmpfile%

:exitzero
exit 0

tolist.txt包含每行1个userid@company.com电子邮件地址列表。

您必须下载blat并将其放入存储库的'hooks'子目录中才能使此命令文件正常工作。

如何知道有人在Tortoise中投放项目的时间

2 个答案: