Question

我希望打电话......

<xsl:call-template name="widow-fix">
  <with-param name="text" select="text"></with-param>
</xsl:call-template>

然后它会查找文本中的最后一个space，并在最终确定时将其替换为#160;。

应该能够支持

Lorem ipsum dolor sit amet, consectetur adipiscing elit.

和

<p>Lorem ipsum dolor sit amet, consectetur adipiscing elit.</p>

请使用其他字符，例如#来回答/证明，因此我测试的结果将是

Lorem ipsum dolor sit amet, consectetur adipiscing#elit.

和

<p>Lorem ipsum dolor sit amet, consectetur adipiscing#elit.</p>

Answer 1

您需要的只是替换每个文本节点中的最后一个空格：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">


<xsl:template match="p | text()">
    <xsl:apply-templates select="." mode="widow-fix"/>
</xsl:template>


<xsl:template match="* | @*">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>


<xsl:template match="* | @*" mode="widow-fix">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()" mode="widow-fix"/>
    </xsl:copy>
</xsl:template>


<xsl:template match="text()[contains(., ' ')]" mode="widow-fix">
    <xsl:call-template name="text">
        <xsl:with-param name="text" select="."/>
    </xsl:call-template>
</xsl:template>


<xsl:template name="text">
    <xsl:param name="text"/>

    <xsl:variable name="substring-before" select="substring-before($text, ' ')"/>
    <xsl:variable name="substring-after"  select="substring-after($text, ' ')"/>

    <xsl:choose>
        <xsl:when test="contains($substring-after, ' ')">
            <xsl:value-of select="$substring-before"/>
            <xsl:text> </xsl:text>

            <xsl:call-template name="text">
                <xsl:with-param name="text" select="$substring-after"/>
            </xsl:call-template>
        </xsl:when>

        <xsl:otherwise>
            <xsl:value-of select="$substring-before"/>
            <!--<xsl:text>&#160;</xsl:text>-->
            <xsl:text>#</xsl:text>
            <xsl:value-of select="$substring-after"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>


</xsl:stylesheet>

mode =“widow-fix”可以处理保留封闭标记的文本节点和段落。

我使用此类文档作为测试源

<book>
<p>Highly random content</p>
in this book
</book>

转换为以下

<book>
<p>Highly random#content</p>
in this#book
</book>

Answer 2

你需要“select = text（）”，你可以使用xs：string函数之一进行替换，但我不会将结果描述为阻止寡妇。

XSL：有一种简单的方法可以防止寡妇吗？

2 个答案: