Question

我在XP机器上使用Delphi 6。

我在stringgrid中使用Onmousemove来获取单元格的内容。然后我使用单元格内容来设置提示。然后我使用Application.ActivateHint来显示提示。但每次更新提示值时，操作系统都会发送另一个MouseMove事件。这会导致提示非常糟糕。

我知道鼠标没有移动，但我充斥着MouseMove事件。 mousemove会导致提示更新导致鼠标移动导致提示更新等。

Answer 1

你采取了完全错误的做法。不要使用OnMouseMove事件手动设置Hint并致电Application.ActivateHint()，而是让VCL为您处理所有事情。

使用TApplication.OnShowHint事件，或者子类化StringGrid来拦截CM_HINTSHOW消息，以自定义StringGrid的本机提示的行为方式。这两种方法都允许您访问THintInfo记录，该记录允许您在显示/更新之前自定义当前提示。特别是，THintInfo.CursorRect成员允许您设置VCL用于跟踪鼠标的矩形，并决定何时/是否需要触发新的OnShowHint事件或CM_HINTSHOW消息以进行更新当鼠标仍在显示提示的控件内时的当前提示。该更新比TApplication.ActivateHint()更清晰，更无缝。

例如：

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.OnShowHint := AppShowHint;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Application.OnShowHint := nil;
end;

procedure TForm1.AppShowHint(var HintStr: string; var CanShow: Boolean; var HintInfo: THintInfo);
var
  Col, Row: Longint;
begin
  if HintInfo.HintControl := StringGrid1 then
  begin
    StringGrid1.MouseToCell(HintInfo.CursorPos.X, HintInfo.CursorPos.Y, Col, Row);
    if (Col >= 0) and (Row >= 0) then
    begin
      HintInfo.CursorRect := StringGrid1.CellRect(Col, Row);
      HintInfo.HintStr := StringGrid1.Cells[Col, Row];
    end;
  end;
end;

或者：

private
  OldWndProc: TWndMethod;

procedure TForm1.FormCreate(Sender: TObject);
begin
  OldWndProc := StringGrid1.WindowProc;
  StringGrid1.WindowProc := StringGridWndProc;
end;

procedure TForm1.StringGridWndProc(var Message: TMessage);
var
  HintInfo: PHintInfo;
  Col, Row: Longint;
begin
  if Message.Msg = CM_HINTSHOW then
  begin
    HintInfo := PHintInfo(Message.LParam);
    StringGrid1.MouseToCell(HintInfo.CursorPos.X, HintInfo.CursorPos.Y, Col, Row);
    if (Col >= 0) and (Row >= 0) then
    begin
      HintInfo.CursorRect := StringGrid1.CellRect(Col, Row);
      HintInfo.HintStr := StringGrid1.Cells[Col, Row];
      Exit;
    end;
  end;
  OldWndProc(Message);
end;

如果您希望在单元格中的每次鼠标移动时更新提示，只需将THintInfo.CursorRect设置为当前THintInfo.CursorPos位置的1x1矩形。如果您希望即使未移动鼠标也要定期更新提示，请将THintInfo.ReshowTimeout设置为非零间隔（以毫秒为单位）。

设置提示时创建的MouseMove事件

1 个答案: