Question

我正在编写一个Perl脚本，它将写入一些输入并将这些输入发送到外部程序。这个程序有一个很小但非零的机会，我想把它计时：

my $pid = fork;
if ($pid > 0){
    eval{
        local $SIG{ALRM} = sub { die "TIMEOUT!"};
        alarm $num_secs_to_timeout;
        waitpid($pid, 0);
        alarm 0;
    };
}
elsif ($pid == 0){
    exec('echo blahblah | program_of_interest');
    exit(0);
}

现在，在$ num_secs_to_timeout之后，program_of_interest仍然存在。我试图在$SIG{ALRM}的匿名子程序中将其杀死，如下所示：

local $SIG{ALRM} = sub{kill 9, $pid; die "TIMEOUT!"}

但这没有做任何事情。 program_of_interest仍然存在。我如何杀死这个过程？

Answer 1

我能够通过终止进程组成功杀死我的exec（）ed进程，如问题In perl, killing child and its children when child was created using open的答案所示。我修改了我的代码如下：

my $pid = fork;
if ($pid > 0){
    eval{
        local $SIG{ALRM} = sub {kill 9, -$PID; die "TIMEOUT!"};
        alarm $num_secs_to_timeout;
        waitpid($pid, 0);
        alarm 0;
    };
}
elsif ($pid == 0){
    setpgrp(0,0);
    exec('echo blahblah | program_of_interest');
    exit(0);
}

超时后，program_of_interest被成功杀死。

Answer 2

上面的代码（严格按照27）并没有开箱即用，因为 - $ PID拼写为大写字母。（顺便说一句：还有：http://www.gnu.org/software/coreutils/manual/html_node/timeout-invocation.html）

这是测试的一个例子：

#!/usr/bin/perl
use strict;
use warnings;
use File::Basename;

my $prg = basename $0;
my $num_secs_sleep = 2;
my $num_secs_to_timeout = 1;
my $orig_program = "sleep $num_secs_sleep; echo \"Look ma, survived!\"";
my $program = $orig_program;
my $expect = "";

if (@ARGV){
  if($ARGV[0] eq "test"){
    test();
    exit 0;
  } elsif (@ARGV == 1) {
    $num_secs_to_timeout = $ARGV[0];
  } elsif (@ARGV == 2) {
    $program = $ARGV[0];
    $num_secs_to_timeout = $ARGV[1];
  } else {
    die "Usage: $prg [ \"test\" | [program] seconds ] "
  }
}

if($orig_program eq $program) {
  if(@ARGV < 2) {
    $expect = $num_secs_to_timeout > $num_secs_sleep ?
      "(we expected to survive.)" : "(we expected to TIME OUT!)";
  }
  print STDERR "sleeping: $num_secs_sleep seconds$/";
}

print STDERR <<END;
  timeout after: $num_secs_to_timeout seconds,
  running program: '$program'
END

if($orig_program eq $program) {
  print STDERR "$expect$/";
}

exit Timed::timed($program, $num_secs_to_timeout);

sub test {
  eval "use Test::More qw(no_plan);";
  my $stdout;
  close STDOUT;
  open STDOUT, '>', \$stdout or die "Can't open STDOUT: $!";
  Timed::timed("sleep 1", 3);
  is($stdout, undef);
  Timed::timed("sleep 2", 1);
  is($stdout, "TIME OUT!$/");
}

################################################################################
package Timed;
use strict;
use warnings;

sub timed {
  my $retval;
  my ($program, $num_secs_to_timeout) = @_;
  my $pid = fork;
  if ($pid > 0){ # parent process
    eval{
      local $SIG{ALRM} = 
        sub {kill 9, -$pid; print STDOUT "TIME OUT!$/"; $retval = 124;};
      alarm $num_secs_to_timeout;
      waitpid($pid, 0);
      alarm 0;
    };
    return defined($retval) ? $retval : $?>>8;
  }
  elsif ($pid == 0){ # child process
    setpgrp(0,0);
    exec($program);
  } else { # forking not successful
  }
}

Answer 3

嗯你的代码对我有用，经过一些小修改后 - 我假设你自己做了一些修改，使代码成为一个通用的例子。

这让我有两个想法：

您在创建示例代码时删除了问题 - 尝试创建一个实际运行的小样本（我必须将'program_of_interest'和$ num_secs_to_timeout更改为实际值来测试它）。确保样品有同样的问题。
这与你正在运行的program_of_interest有关 - 据我所知，你无法掩盖kill 9，但也许还有一些事情正在发生。您是否尝试使用非常简单的脚本测试代码。我为我的测试创建了一个（1）{print“hi \ n”;睡1; }
其他。

Answer 4

可以忽略SIGKILL的唯一方法是进程是否在一个不可中断的系统调用中。如果状态为D，则检查挂起进程的状态（使用ps aux），然后无法终止该进程。

您可能还想通过从中输出内容来检查是否正在调用该函数。

如何超时可能挂起的分叉进程？

4 个答案: