Question

我正在尝试找到一种方法让我的代码等待两秒钟才能继续。我在保护模式下使用nasm for Linux，所以我只能使用int 80h。我找到了一个名为“syscall”的alarm（27），另一个名为“pause”（29）。但是，当我尝试使用它们时，程序会等待并完成，而不是继续执行。我还发现了另一个syscall，sigaction，它改变了信号的行为（所以我认为它可以用来使程序忽略由报警而不是退出产生的信号）但我不太明白sigaction如何工作。谢谢你的帮助。有用的链接：http://man7.org/linux/man-pages/man2/alarm.2.html http://man7.org/linux/man-pages/man2/sigaction.2.html

Answer 1

系统调用睡眠程序sys_nanosleep：

 sys_nanosleep : eax = 162, ebx = struct timespec *, ecx = struct timespec *

此struct timespec结构有两个成员：

tv_sec   ; 32 bit seconds
tv_nsec  ; 32 bit nanoseconds

这个结构可以在nasm中声明为：

section .data

  timeval:
    tv_sec  dd 0
    tv_usec dd 0

然后设置值并将其命名为：

mov dword [tv_sec], 5
mov dword [tv_usec], 0
mov eax, 162
mov ebx, timeval
mov ecx, 0
int 0x80

程序然后会睡5秒钟。一个完整的例子：

global  _start

section .text
_start:

  ; print "Sleep"
  mov eax, 4
  mov ebx, 1
  mov ecx, bmessage
  mov edx, bmessagel
  int 0x80

  ; Sleep for 5 seconds and 0 nanoseconds
  mov dword [tv_sec], 5
  mov dword [tv_usec], 0
  mov eax, 162
  mov ebx, timeval
  mov ecx, 0
  int 0x80

  ; print "Continue"
  mov eax, 4
  mov ebx, 1
  mov ecx, emessage
  mov edx, emessagel
  int 0x80

  ; exit
  mov eax, 1
  mov ebx, 0
  int 0x80

section .data

  timeval:
    tv_sec  dd 0
    tv_usec dd 0

  bmessage  db "Sleep", 10, 0
  bmessagel equ $ - bmessage

  emessage  db "Continue", 10, 0
  emessagel equ $ - emessage

Answer 2

使用NASM，如果您的目标是Linux x86-64，您可以执行类似以下操作：

global _start

section .data

    timespec:
        tv_sec  dq 1
        tv_nsec dq 200000000

section .text

    _start:
        mov rax, 35
        mov rdi, timespec
        xor rsi, rsi        
        syscall
        ...

35对应sys_nanosleep的64位系统调用号（如列出的here）。如果呼叫中断，剩余的休眠时间将写入寄存器rsi指向的存储器位置;在此示例中，rsi设置为0以在发生时忽略该值。此调用将在 tv_sec seconds + tv_nsec nanoseconds 中休眠，在上面的代码片段中为1.2秒。

有关此系统调用的更多信息，请参阅nanosleep man page。

nasm汇编linux计时器或睡眠

2 个答案: