Question

declare @emp table
(
  EmployeeId int, CompanyId int ,FirstName nvarchar(50),MiddleName nvarchar(50) ,LastName  nvarchar(50)
)

insert into @emp select 1,1,'rahul','kumar','Sharma'
insert into @emp select 16,1,'nitin','','Sharma'

select * From @emp

declare @PayInformation table
(
  EmployeeId int ,IsHourly bit ,PayFrequency nvarchar(50) ,Amount decimal(18,2),StandardHours decimal(18,2)  ,Year int,Sequence int
)


 insert into @PayInformation select 1,0,'monthly',40.00,40,2013,1
 insert into @PayInformation select 1,0,'monthly',100.00,40,2013,2
 insert into @PayInformation select 16,0,'monthly',100.00,40,2013,2

 select * From @PayInformation

 select * from @emp as e 
 inner join @PayInformation as p ON e.EmployeeId=p.EmployeeId

这个连接语句给我3行，因为EmployeeId 1在PayInformation表中有2行。但我想加入只有最大序列号的行。因此，根据我想要的结果，它应该与员工1的序列号2一起加入。

Answer 1

有几种方法可以做到这一点

首先：

select * 
from @emp as e 
    outer apply (
        select top 1 t.*
        from @PayInformation as t
        where t.EmployeeId=e.EmployeeId
        order by t.Sequence desc
    ) as p

第二

select * 
from @emp as e 
    left outer join @PayInformation as p on p.EmployeeId=e.EmployeeId
where
    exists (
        select 1
        from @PayInformation as t
        where t.EmployeeId=e.EmployeeId
        having max(t.Sequence) = p.Sequence
   )

第三

;with cte_PayInformation as (
    select *, row_number() over(partition by EmployeeId order by Sequence desc) as rn
    from @PayInformation
)
select * 
from @emp as e 
    left outer join cte_PayInformation as p on p.EmployeeId = e.EmployeeId and p.rn = 1

<强> sql fiddle demo

快速注意 - 这些查询不等效，如果Sequence, EmployeeId表中有@PayInformation重复，则第二个可能会返回更多行。

仅与具有最大序列号的行连接

1 个答案: