Question

我编写了一个包含一个函数的脚本，该函数应循环遍历列表并返回给定所述列表中项目索引的值。我有一个名为:find的函数，它应该有2个参数：列表和项目位置。我不确定如何处理函数中的多个参数。如果我在循环中用%LIST%替换%MY_LIST%并且从参数列表中删除%MY_LIST%并将其传递给call :find，则此脚本运行正常，但我真的想知道如何传递多个参数。我认为它们只是作为整个字符串传递给函数...

@echo off
setlocal enableDelayedExpansion
cls

:: ----------------------------------------------------------
:: Variable declarations
:: ----------------------------------------------------------
set RETURN=-1
set MY_LIST=("foo" "bar" "baz")
set TARGET_INDEX=1

:: ----------------------------------------------------------
:: Main procedure
:: ----------------------------------------------------------
call :log "Finding item %TARGET_INDEX%..."
call :find %MY_LIST% %TARGET_INDEX%
call :log "The value is: %RETURN%"
goto Exit

:: ----------------------------------------------------------
:: Function declarations
:: ----------------------------------------------------------
:find
call :log "Called `:find` with params: [%*]"
set /a i=0
set LIST=%~1 & shift

for %%a in %LIST% do (
    if !i! == %~1 (
        set RETURN=%%a
    )
    set /a i=!i!+1
)
goto:EOF

:printDate
for /f "tokens=2-4 delims=/ " %%a in ('echo %DATE%') do (
  set mydate=%%c/%%a/%%b)
for /f "tokens=1-3 delims=/:./ " %%a in ('echo %TIME%') do (
  set mytime=%%a:%%b:%%c)
echo|set /p="[%mydate% %mytime%] "
goto:EOF

:log
call :printDate
echo %~1
goto:EOF

:: ----------------------------------------------------------
:: End of script
:: ----------------------------------------------------------

:Exit

更新

我的脚本现在运行正常;感谢nephi12。 http://pastebin.com/xGdFWmnM

Answer 1

call :find "%MY_LIST%" %TARGET_INDEX%
goto :EOF

:find
echo %~1 %~2
goto :EOF

它们与args一样传递给脚本... ;)

Answer 2

这是另一种在空格分隔的值列表上执行索引查找的方法。定义列表而不括括号。单词不需要引用。必须引用带有空格，制表符，分号或相等的短语。此外，还应引用包含&和|等特殊字符的值。

然后颠倒你的：FIND参数的顺序 - 首先是索引，然后是实际的列表。在FOR / L循环中使用SHIFT将所需的索引值放入第一个参数中。

此解决方案的一个优点是它可以支持任意数量的值，只要它们符合每行8191个字符的限制。 nephi12解决方案限制为9个值。

@echo off
setlocal
set MY_LIST=foo bar baz "Hello world!"
call :find %~1 %MY_LIST%
echo return=%return%
exit /b

:find  index  list...
for /L %%N in (1 1 %~1) do shift /1
set "return=%~1"
exit /b

Answer 3

试试这个，我想它会回答你的问题。把它放在一个bat文件中，然后在看到这个工作后再构建你需要的任何东西。使用命令提示符中的带引号的字符串执行它。 YourBatFile“Arg1 Arg2 Arg3 Etc”

@echo off
call :DoSomethingWithEach %~1
goto :eof

:DoSomethingWithEach
for %%a in (%*) do echo.%%a
goto :eof

批处理脚本传递多个参数进行调用

3 个答案: