Question

我有一个类似于以下内容的XML文档。

<library>
  <artist name="a">
   <album name="1"></album>
   <album name="2"></album>
  </artist>
  <artist name="b">
   <album name="8"></album>
   <album name="9"></album>
  </artist>
</library>`

我在Ubuntu上用Vala编写应用程序，并使用libxml2库来操作XML文档。我想获取所有album个节点，而不管它们在文档中的位置。我已经编写了以下代码来完成上述工作。

document = Xml.Parser.parse_file (PATH_TO_DB);
...
Xml.XPath.Context context;
unowned Xml.XPath.Object *object;

context = new Xml.XPath.Context(document);
object = context.eval("//album");

if(object->nodesetval->is_empty())
    return null;

return object->nodesetval->item(0);
...

此XPath查询仅返回artist a下的相册，即相册1和2.但context.eval("/library/artist[@name="b"]/album");将返回artist b下的所有相册。

上面显示的代码的python等效产生了所需的结果。

doc = libxml2.parseFile("data.xml")
ctxt = doc.xpathNewContext()
res = ctxt.xpathEval("//album")

Vala代码有什么问题？

Answer 1

首先，您应该通过检查object->type == Xml.ObjectType.NODESET来检查返回的对象是否为NodeSet。

接下来，您只返回结果节点集中的第一个项目。有nodeset->length()项。

void main() {
    var document = Xml.Parser.parse_file ("file.xml");
    run_query("//album", document);
    run_query("/library/artist[@name=\"b\"]/album", document);
}

void run_query(string query, Xml.Doc* document) {
    stdout.printf("Query: %s\n", query);
    Xml.XPath.Context context;
    unowned Xml.XPath.Object *object;

    context = new Xml.XPath.Context(document);
    object = context.eval(query);
    assert(object->type == Xml.XPath.ObjectType.NODESET);

    if(object->nodesetval->is_empty()) {
        stdout.printf("empty");
        return;
    }

    for (var i = 0; i < object->nodesetval->length(); i++) {
        var node = object->nodesetval->item(i);
        stdout.printf("node %s name=\"%s\"\n", node->name, node->get_prop("name"));
    }
}

产地：

Query: //album
node album name="1"
node album name="2"
node album name="8"
node album name="9"
Query: /library/artist[@name="b"]/album
node album name="8"
node album name="9"

在libxml2中使用XPath选择节点

1 个答案: