Question

我有一个conf文件，其格式为variable =“value”，其中值也可能包含特殊字符。示例行是：

LINE_D =“（L＃'id'=='log'）AND L＃'id'IS NULL”

我有另一个文件F，它应该替换基于此conf文件的值。例如，如果F中有行打印'$ LINE_D' 它应该被替换为 PRINT'（L＃'id'=='log'）AND L＃'id'IS NULL'

如何在shell脚本中使用conf和F并生成F中的值的程序。

由于

Answer 1

您对所需内容的定义会留下很多空白，因此您可能需要调整此脚本。它是最初设计用于处理makefile的更复杂脚本的简化版本。这意味着可能有一些材料可以从这里移除而不会造成麻烦，尽管我已经摆脱了大部分无关的处理。

#!usr/bin/env perl
#
# Note: this script can take input from stdin or from one or more files.
# For example, either of the following will work:
#   cat config file | setmacro
#   setmacro file

use strict;
use warnings;
use Getopt::Std;

# Usage:
# -b -- omit blank lines
# -c -- omit comments
# -d -- debug mode (verbose)
# -e -- omit the environment

my %opt;
my %MACROS;
my $input_line;

die "Usage: $0 [-bcde] [file ...]" unless getopts('bcde', \%opt);

# Copy environment into hash for MAKE macros
%MACROS = %ENV unless $opt{e};

my $rx_macro = qr/\${?([A-Za-z]\w*)}?/;     # Matches $PQR} but ideally shouldn't

# For each line in each file specified on the command line (or stdin by default)
while ($input_line = <>)
{
    chomp $input_line;
    do_line($input_line);
}

# Expand macros in given value
sub macro_expand
{
    my($value) = @_;
    print "-->> macro_expand: $value\n" if $opt{d};
    while ($value =~ $rx_macro)
    {
        print "Found macro = $1\n" if $opt{d};
        my($env) = $MACROS{$1};
        $env = "" unless defined $env;
        $value = $` . $env . $';
    }
    print "<<-- macro_expand: $value\n" if $opt{d};
    return($value);
}

# routine to recognize macros
sub do_line
{
    my($line) = @_;
    if ($line =~ /^\s*$/o)
    {
        # Blank line
        print "$line\n" unless $opt{b};
    }
    elsif ($line =~ /^\s*#/o)
    {
        # Comment line
        print "$line\n" unless $opt{c};
    }
    elsif ($line =~ /^\s*([A-Za-z]\w*)\s*=\s*(.*)\s*$/o)
    {
        # Macro definition
        print "Macro: $line\n" if $opt{d};
        my $lhs = $1;
        my $rhs = $2;
        $rhs = $1 if $rhs =~ m/^"(.*)"$/;
        $MACROS{$lhs} = ${rhs};
        print "##M: $lhs = <<$MACROS{$lhs}>>\n" if $opt{d};
    }
    else
    {
        print "Expand: $line\n" if $opt{d};
        $line = macro_expand($line);
        print "$line\n";
    }
}

给定一个配置文件cfg，其中包含：

LINE_D="(L#'id' == 'log') AND L#'id' IS NULL"

和另一个文件F，其中包含：

PRINT '$LINE_D'
PRINT '${LINE_D}'

perl setmacro.pl cfg F的输出是：

PRINT '(L#'id' == 'log') AND L#'id' IS NULL'
PRINT '(L#'id' == 'log') AND L#'id' IS NULL'

这匹配了所需的输出，但是给了我带有多个单引号的heebie-jeebies。但是，客户永远是对的！

（我想我已经摆脱了残留的Perl 4-isms;基本脚本仍然留下了一些遗留物，以及一些关于Perl 5.001如何处理不同内容的评论。它确实使用了$`和$'这通常不是一个好主意。但是它有效，所以修复这个是读者的练习。正则表达式变量现在不是必需的;它是在识别make宏表示法的时候 - $(macro)以及${macro}。）

根据conf文件替换文件的值

1 个答案: