Question

我正在尝试将Report（或Form）的记录集更改为Report_Load事件中动态调用的MySQL存储过程的结果。具体来说，我该如何设置连接？

我查看了Bind Access form to the results from a Stored Procedure以及How to bind Microsoft Access forms to ADO recordsets。我已经使用pass-thru查询中的硬编码值成功连接到存储过程，详见Calling Stored Procedures and other SQL statements from MS Access 2003 (Pass Through)。

以下是来自Bind Access form to the results from a Stored Procedure的示例代码 - 我想设置连接以使用MySQL而不是SQL Server：

With cn
    .Provider = "Microsoft.Access.OLEDB.10.0"
    .Properties("Data Provider").Value = "SQLOLEDB"
    .Properties("Data Source").Value = "Server"
    .Properties("Integrated Security").Value = "SSPI"
    .Properties("Initial Catalog").Value = "Test"
    .Open
End With

我正在使用Access 2007。

出于兴趣，这里是我用来尝试修改sp调用的代码，给出错误“32585此功能仅在ADP中可用”。 Gord Thompson建议修改实际查询，因此我正在使用它。

    If Not CurrentProject.AllForms("foo_frm").IsLoaded Then
        'use hard-coded query (stored procedure) for dev work
        Exit Sub
    End If

    Dim action, startdate, enddate As String
    action = Forms![foo_frm].txtAction

    If action = "cmdDaily" Then
        startdate = Forms![foo_frm].txtYesterday
        enddate = Forms![foo_frm].txtToday
    Else
        startdate = Forms![foo_frm].cboStartDate
        enddate = Forms![foo_frm].cboEndDate
    End If

    Dim cn As New ADODB.Connection
    Dim strConnection As String

    strConnection = "ODBC;DSN=Foo01;UID=root;PWD=Secret;DATABASE=bar"
    With cn
       .Provider = "MSDASQL"
       .Properties("Data Source").Value = strConnection
       .Open
    End With

    Dim prmStartDate, prmEndDate As New ADODB.Parameter
    Dim cmd As New ADODB.Command

    Set prmStartDate = cmd.CreateParameter("startdate", adDate, adParamInput)
    prmStartDate.Value = CDate(startdate)
    cmd.Parameters.Append (prmStartDate)

    Set prmEndDate = cmd.CreateParameter("enddate", adDate, adParamInput)
    prmEndDate.Value = CDate(enddate)
    cmd.Parameters.Append (prmEndDate)

    With cmd
        .ActiveConnection = cn
        .CommandText = "qux_sp"
        .CommandType = adCmdStoredProc
        Set Me.Recordset = .Execute
    End With

Answer 1

您已经让报告使用了传递查询，因此，不要使用代码来处理报告的行源，为什么不将报告绑定到传递查询并使用代码来调整其SQL声明并使用您想要的参数调用存储过程？

例如，以下VBA代码......

Sub TweakPassThroughQuery()
Dim testID As Long
Dim qdf As DAO.QueryDef, rst As DAO.Recordset
testID = 2  ' this is the parameter we really want to pass to the stored procedure
Set qdf = CurrentDb.QueryDefs("ptq_myproc")
Debug.Print "Existing pass-through query..."
Debug.Print "    " & qdf.SQL
Set rst = qdf.OpenRecordset
Debug.Print "...returns a value like this:"
Debug.Print "    " & rst!col1
rst.Close
Set rst = Nothing
' now tweak the stored procedure call
qdf.SQL = "CALL myproc(" & testID & ")"
Debug.Print "Modified pass-through query..."
Debug.Print "    " & qdf.SQL
Set rst = qdf.OpenRecordset
Debug.Print "...returns a value like this:"
Debug.Print "    " & rst!col1
rst.Close
Set rst = Nothing
Set qdf = Nothing
End Sub

...显示以下输出：

Existing pass-through query...
    CALL myproc(1)
...returns a value like this:
    foo
Modified pass-through query...
    CALL myproc(2)
...returns a value like this:
    bar

将访问表单/报告绑定到MySQL存储过程的结果

1 个答案: