Question

我在db中有一个字符串值。我需要在每3个字符之间插入一个,。这是示例字符串。

示例字符串

111100120125     // This sample is a dynamic string. So It can be less or more ..

结果

Val = 111,100,120,125

请告诉我内置的SqlServer函数，以便得到,分隔的字符串。

对此有任何帮助将不胜感激。

感谢。

Answer 1

请告诉我内置的SqlServer函数来获取，结果是分开的字符串。

您可以使用 Stuff() 功能。 Fiddle demo 特定于您的字符串。

Declare @S varchar(50) = '111100120125'

SELECT STUFF(STUFF(STUFF(@S,4,0,','),8,0,','),12,0,',')

111,100,120,125

编辑：更通用的解决方案是创建一个如下所示的函数（注意，此函数开始从末尾插入分隔符值）：

CREATE FUNCTION dbo.AddSeparator (@String VARCHAR(max), @Separator VARCHAR(1))
RETURNS VARCHAR(max)
AS
BEGIN

    Declare @Length int = Len(@String)
    WHILE (@Length > 3)
    BEGIN
    SELECT @String = STUFF(@String, @Length - 2, 0, @Separator),
           @Length = @Length -3
    END

    RETURN @String
END;

用法和 fiddle demo ：

SELECT String Original, dbo.AddSeparator(String, ',') Modified
FROM T

结果：

| ORIGINAL |  MODIFIED |
|----------|-----------|
|          |           |
|        1 |         1 |
|       12 |        12 |
|      123 |       123 |
|     1234 |     1,234 |
|    12345 |    12,345 |
|   123456 |   123,456 |
|  1234567 | 1,234,567 |

Answer 2

您可以使用递归CTE：

declare @f varchar(100)='111100120125'
;with pos as(
select 3 n, cast(SUBSTRING(@f,1,3) as varchar(max)) a
union all
select n+3 n, a+','+ SUBSTRING(@f,n+1,3) from pos
where n<LEN(@f)
)
select max(@f) ini, max(a) res from pos;

在Sql Server中分为3个字符

2 个答案: