Question

我有excel文件，有5个级别的缩进，所以我想我需要Spreadsheet::ParseExcel::Format 但当我正在尝试$format->{Indent}时（就像在概要中一样）perl说：

Global symbol "$format" requires explicit package name

我尝试了不同的方式，Spreadsheet::ParseExcel::Format->new()和其他方式，但仍然没有成功。

什么是正确的概要或是否有其他方法来解析xls文件中的缩进？也许一些二进制？（xlhtml和xls2csv根本不关心缩进:(）

Answer 1

由@mpapec链接的网站似乎声称有一个John McNamara的解决方案：

#!/usr/bin/perl -w

use strict;
use Spreadsheet::ParseExcel;

my $parser   = Spreadsheet::ParseExcel->new();
my $workbook = $parser->parse('Book1.xls');

if ( !defined $workbook ) {
    die $parser->error(), ".\n";
}

for my $worksheet ( $workbook->worksheets() ) {

    my ( $row_min, $row_max ) = $worksheet->row_range();
    my ( $col_min, $col_max ) = $worksheet->col_range();

    for my $row ( $row_min .. $row_max ) {
        for my $col ( $col_min .. $col_max ) {

            my $cell = $worksheet->get_cell( $row, $col );
            next unless $cell;

            my $format = $cell->get_format();

            print "Row, Col    = ($row, $col)\n";
            print "Value       = ", $cell->value(), "\n";
            print "Indent      = ", $format->{Indent}, "\n";

            print "\n";
        }
    }
}
__END__

使用缩进解析.xls文件

1 个答案: