Question

我需要在Window *.bat文件中获取今天的日期。在它之后我想得到日，月和年。我怎样才能做到这一点？
我无法使用PowerShell

Answer 1

这将为您提供DD MM YYYY YY HH Min Sec变量，适用于XP Pro及更高版本的任何Windows计算机。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

Answer 2

你得到这样的格式

for /f "tokens=1-4 delims=/ " %%i in ("%date%") do (
     set dow=%%i
     set month=%%j
     set day=%%k
     set year=%%l
)
set datestr=%month%_%day%_%year%
echo datestr is %datestr%

Answer 3

%date%会给你日期。

%time%会给你时间。

date和time /t命令可能会为您提供更多详细信息。

Answer 4

set datestr=%date%
set result=%datestr:/=-%
@echo %result%
pause

Answer 5

与区域设置无关的一个班轮，可以获得您喜欢的任何日期格式。我用它来生成档案名称。需要返回引号选项，因为PowerShell命令行使用单引号。

:: Get date in yyyyMMdd_HHmm format to use with file name.
FOR /f "usebackq" %%i IN (`PowerShell ^(Get-Date^).ToString^('yyyy-MM-dd'^)`) DO SET DTime=%%i

:: Get formatted yesterday date.
FOR /f "usebackq" %%i IN (`PowerShell ^(Get-Date^).AddDays^(-1^).ToString^('yyyy-MM-dd'^)`) DO SET DTime=%%i

:: Show file name with the date.
echo Archive.%DTime%.zip

如何在BAT文件中获取日期

5 个答案: