Question

我正在努力将一个字符串绑定到我在Outlook VBA中所需的内容。我已尝试过来自互联网的100种不同的东西，包括这里。

我使用以下内容：

CString = LTrim$(RTrim$(Mid(itm.Body, InStr(1, itm.Body, CCMark) + Len(CCMark), _
            InStr(InStr(1, itm.Body, CCMark) + Len(CCMark), itm.Body, CCMark) - (InStr(1, itm.Body, CCMark) + Len(CCMark)))))

CCMark =“C /”

但由于电子邮件正文包含：C / test C /，变量（CString）进入“测试”。

我尝试过使用Trim，RTrim，LTrim，Trim $，LTrim $和RTrim $的第二个变量。另外，我已经尝试了具有双倍空间和单个空间的REPLACE。我尝试过在互联网上流行的TrimAll函数，它试图找到不同的Chr（）值以及vbTab等。这些函数似乎都没有替换任何东西。

字符串保持不变。

这是一个固定长度与可变长度（“大小”）的字符串问题吗？我还没有找到一种从固定长度转换为变量的方法。通过一个函数没有奏效。

关于如何以“测试”作为结果的任何建议？

非常感谢你的帮助。

Answer 1

简单地说：VBA中的字符串处理功能确实有效。如果您的字符串在输入字符串的开头或结尾处有空格字符（特别是具有代码点32的字符），那么它们将被删除。

“固定长度”字符串仅在您使用特殊语法明确声明它们时才存在：

Dim eightCharString As String(8)  ' This is a fixed-length string

没有VBA字符串函数返回固定长度的字符串。因此，除非您使用上述表示法将CString声明为固定长度字符串，否则这不是问题。

逻辑上唯一的可能性是你认为空格的字符实际上不是空格。电子邮件中极有可能的候选者是它们是HTML不间断空格字符或代码点0xA0（十进制160）。到目前为止，替换源字符串中多个字符的最简单方法是使用正则表达式。

这是典型的基于正则表达式的修剪功能。下面构造的两种模式是

Start pattern: "^[\u0009\u0020\u00A0]*"
End pattern:   "[\u0009\u0020\u00A0]*$"

如果要查找和删除其他空格字符，只需将其代码点值添加到下面函数的列表中。例如，要将换行符和回车符视为要修剪的空格，请将代码点10和13添加到列表中。

代码：

Private m_RxTrimStart As RegExp
Private m_RxTrimEnd   As RegExp 

Public Function RxTrim(ByRef Source As String) As String 

    ' Only create and compile the RegExp objects once
    If m_RxTrimStart Is Nothing Then

        ' A verbose way of constructing the regex object so you
        ' can see exactly what's going on  
        Dim spaceCodePoints As Variant, vCodePoint
        Dim strSpaceClass As String, strHexPoint As String

        ' Add additional code points here if desired
        spaceCodePoints = Array(9, 32, 160)
        strSpaceClass = "["
        For Each vCodePoint In spaceCodePoints
            ' Assemble a four-character hex code point 
            strHexPoint   = Hex$(CLng(vCodePoint))
            strHexPoint   = String("0", 4 - Len(strHexPoint)) & strHexPoint
            strSpaceClass = strSpaceClass & "\u" & strHexPoint
        Next 
        strSpaceClass = strSpaceClass & "]*" 

        ' Start anchor + spaces character class
        Set m_RxTrimStart = New RegExp
        m_RxTrimStart.Pattern = "^" & strSpaceClass

        ' Spaces character class + end anchor
        Set m_RxTrimEnd   = New RegExp
        m_RxTrimEnd.Pattern   = strSpaceClass & "$"
    End If

    RxTrim = m_RxTrimEnd.Replace(m_RxTrimStart.Replace(Source, ""), "")

End Function

Outlook VBA - 修剪不可打印的字符

1 个答案: