Question

我有我的xsl来转换xml_file_1。我将xml_file_2包含在xsl的输出中。

例如，输出文件的结构是：

<A>
    <B>
        <!-- inject external xml here -->
        <C/>
    </B>
</A>

怎么做？

我尝试使用以下收据：

<xsl:template match="/">
  <xsl:copy-of select="document('external.xml')/*"/>
</xsl:template>

但它只是用外部文件的内容替换输出文件。我尝试了上述模板的不同变体，比如指向match =“/”到我需要插入的节点（match =“/ A / B”）但没有结果。

P.S。在使用xsl之前，我将使用sed从外部文件中删除第一行<?xml version="1.0" encoding="utf-8"?>。

Answer 1

我认为注射点应该用以下元素标记：

<?xml version="1.0" encoding="UTF-8"?>
<A>
    <B>
        <InjectionPoint />
        <C/>
    </B>
</A>

让external.xml为

<?xml version="1.0" encoding="UTF-8"?>
<ExternaFile>
    <Content1 />
    <Content2 />
</ExternaFile>

然后可以使用稍加修改的identity transform

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <!-- Identity transform-->
    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*" />
        </xsl:copy>
    </xsl:template>

    <!-- Replacing inject point element-->
    <xsl:template match="InjectionPoint">
        <xsl:copy-of select="document('external.xml')" />
    </xsl:template>

</xsl:stylesheet>

，结果是

<?xml version="1.0" encoding="UTF-8"?>
<A>
    <B>
        <ExternaFile>
            <Content1/>
            <Content2/>
        </ExternaFile>
        <C/>
    </B>
</A>

顺便说一句，你不需要用sed剥离xml序言。

编辑：我不想使用特殊元素标记正确的位置，你可以使用像

这样的模板

<!--or without "inject" element -->
<xsl:template match="B[parent::A]">
    <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:copy-of select="document('external.xml')" />
        <xsl:apply-templates select="node()" />
    </xsl:copy>
</xsl:template>

但是可能会出现几个问题（例如，当A元素中有更多B元素，当有多个A元素包含B元素等时。）

使用xslt 1.0将外部xml注入主xml

1 个答案: