Inno设置：运行程序而不显示复选框

Question

我有以下几行：

[Run]
Filename: "{app}\MyApp.exe"; Flags: postinstall nowait

我希望我的应用程序在没有显示复选框的情况下启动（这将禁止用户这样做）。

有人可以告诉我怎么样吗？ 谢谢。

Answer 1

我能想到的选择很少。第一个是从脚本的[Code]部分运行您的应用程序，第二个是禁用[Run]部分条目的复选框，第三个是隐藏RunList }。

1。如何在向导完成后手动运行应用程序？

我个人更喜欢这种方式，因为它比添加复选框并稍后隐藏它更简单。您将删除当前[Run]部分条目，并在CurPageID参数等于wpFinished时从NextButtonClick事件方法调用以下函数之一，这表示单击完成按钮：

• Exec - 使用与Setup / Uninstall相同的凭据执行指定的可执行文件或批处理文件。
• ExecAsOriginalUser - 使用最初启动安装程序的用户的（通常是非提升的）凭据执行指定的可执行文件或批处理文件
• ShellExec - 使用与Setup / Uninstall相同的凭据打开指定文件或执行Verb指定的其他操作。
• ShellExecAsOriginalUser - 使用最初启动安装程序的用户的（通常是非提升的）凭据，打开指定的文件或执行Verb指定的其他操作。

由于您尚未使用runascurrentuser或shellexec标志，因此安装程序在内部调用类似于此的函数：

function NextButtonClick(CurPageID: Integer): Boolean;
var
  ResultCode: Integer;
begin
  Result := True;
  if CurPageID = wpFinished then
    ExecAsOriginalUser(ExpandConstant('{app}\MyApp.exe'), '', '', 
      SW_SHOWNORMAL, ewNoWait, ResultCode);
end;

此解决方案的一个缺点是，即使设置请求重新启动，程序也会执行。要解决缺少确定此请求的可能性，我们可以检查YesRadio是否可见（它是是，立即重新启动计算机单选按钮）并选中，这意味着用户是要求重新启动计算机并确认。以下是考虑重启请求的版本：

function NextButtonClick(CurPageID: Integer): Boolean;
var
  ResultCode: Integer;
begin
  Result := True;
  // if the "Finish" button was clicked and "Yes, restart the computer now"
  // radio button was either not visible or not selected that time, then...
  if (CurPageID = wpFinished) and ((not WizardForm.YesRadio.Visible) or 
    (not WizardForm.YesRadio.Checked))
  then
    ExecAsOriginalUser(ExpandConstant('{app}\MyApp.exe'), '', '', 
      SW_SHOWNORMAL, ewNoWait, ResultCode);
end;

2。如何在最后一页上禁用安装后复选框？

另一个选项是禁用复选框。用户将看到应用程序将被执行，但无法对其执行任何操作（当然，除了从任务管理器中删除设置）。这次您将保留[Run]部分条目，但修改RunList部分中的[Code]：

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName=My Program

[Files]
Source: "MyApp.exe"; DestDir: "{app}"

[Run]
Filename: "{app}\MyApp.exe"; Flags: postinstall nowait

[Code]
procedure CurPageChanged(CurPageID: Integer);
begin
  // you must do this as late as possible, because the RunList is being modified
  // after installation; so this will check if there's at least one item in the
  // RunList and then set to the first item (indexing starts at 0) Enabled state
  // to False
  if (CurPageID = wpFinished) and (WizardForm.RunList.Items.Count > 0) then
    WizardForm.RunList.ItemEnabled[0] := False;
end;

3。如何完全隐藏RunList？

与第二种选择相反，这将是您所要求的。它会隐藏复选框，或者更准确地说，它会隐藏整个RunList，因此如果您在[Run]部分中有多个条目并带有postinstall标记指定，它也不会被看到：

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName=My Program

[Files]
Source: "MyApp.exe"; DestDir: "{app}"

[Run]
Filename: "{app}\MyApp.exe"; Flags: postinstall nowait

[Code]
procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then
    WizardForm.RunList.Visible := False;
end;

Answer 2

适用于版本5.5.7

如果您想自动打开网站，请添加以下代码

[Code]
procedure CurPageChanged(CurPageID: Integer);
var
  ErrorCode : Integer ;
begin
  if CurPageID = wpFinished then
    ShellExecAsOriginalUser('', ExpandConstant('http:\\www.google.pt'), '', '',SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;