Question

我有一些代码，我在Oracle PL / SQL中创建一个引用游标，以便能够遍历生成的行。该表有一个大的管道分隔的文本字符串列，然后我循环以获取x位置数组值

（例如：如果线条都像'Mike |男| 100 |是| UK'和'Dave |男| 200 | No | UK'那么我有一个公式允许将数组位置传递给函数返回结果值的数组

数组位置1调用返回'Mike'和'Dave' 数组位置2调用返回'男性'和'男性'

如果我希望能够有一个返回数组位置的不同值的函数，那么接近它的最佳方法是什么

所以数组位置1调用将返回2 数组位置2调用将返回1

我是PL / SQL的新手，请原谅这个愚蠢的问题！

不幸的是，将源表拆分为单独的列不是一个选项： - （

非常感谢

麦克

回应@ zero323（为此错过道歉）

到目前为止的示例代码是......

FUNCTION DistinctInterfacelineValues(
    inArrayPos     NUMBER,
    inSessionIdMIN NUMBER,
    inSessionIdMAX NUMBER)
  RETURN NUMBER
AS
  int_cursor interfaceline_refcursor_type;
  runningTotal NUMBER:=0;
  tempValue    NUMBER:=0;
  int_record inttestintrecs%ROWTYPE;
  lineLength INTEGER:=1;
  distinctCount NUMBER:=0;

  TYPE table_type IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER; 
  tempTable  table_type;
  tempTablePos INTEGER:=1;

BEGIN

 OPEN int_cursor FOR SELECT * FROM inttestintrecs WHERE (sessionid>=inSessionIdMIN AND sessionid <=inSessionIdMAX);
  LOOP
    FETCH int_cursor INTO int_record;
    EXIT
  WHEN int_cursor%NOTFOUND;
    lineLength := LENGTH(int_record.interfaceline) - LENGTH(REPLACE(int_record.interfaceline, '|', '')) + 1;
    FOR i                                         IN 1 .. lineLength
    LOOP
      IF i            =inArrayPos THEN
***VALUE HERE IS 'Mike' or 'Dave' DEPENDING ON LOOP POSITION***
***I WANT TO KNOW COUNT THE DISTINCT VALUES HERE***
      END IF;
    END LOOP;
  END LOOP;
  CLOSE int_cursor;
  RETURN runningTotal;



END DistinctInterfacelineValues;

Answer 1

你真的不需要PL / SQL;你可以使用regexp_substr：

select count(distinct value)
from (
  select regexp_substr(interfaceline, '[^|]+', 1, :arrayPos) as value
  from inttestintrecs
  where sessionid between :loSessId and :hiSessId
);

...其中绑定变量是您传递给函数的值。如果你真的想要一个函数，你可以包装查询（用tbone的replace技巧更新来处理空值）：

create or replace function DistinctInterfacelineValues(
    inArrayPos     NUMBER,
    inSessionIdMIN NUMBER,
    inSessionIdMAX NUMBER)
  RETURN NUMBER
AS
  distinctCount NUMBER;
BEGIN
  select count(distinct value)
  into distinctCount
  from (
    select trim(regexp_substr(replace(interfaceline, '|', ' |'),
      '[^|]+', 1, inArrayPos)) as value
    from inttestintrecs
    where sessionid between inSessionIdMIN and inSessionIdMAX
  );
  RETURN distinctCount;
END;
/

SQL Fiddle demo

在您发布的嵌套循环版本中，您可以维护一个由值而不是数字索引的PL / SQL表：

...
  TYPE table_type IS TABLE OF NUMBER INDEX BY VARCHAR2(100); 
  tempTable  table_type;
  tempValue VARCHAR2(100);
...
      IF i = inArrayPos THEN
        tempValue := regexp_substr(int_record.interfaceline, '[^|]+', 1, i);
        tempTable(tempValue) := 1;
      END IF;
...
  RETURN tempTable.count;
...

Another Fiddle只是为了好玩，但实际上没有任何PL / SQL循环开销，特别是中间的regexp_substr。您可以为每个值增加tempTable中的计数，这样您就可以知道每个人看到的数量，并且您也可以从tempTable获得实际值......但是您可以从纯SQL版本同样容易（选择value, count(*)和distinct value）。

DISTINCT指望Oracle PL / SQL中的ref_cursor

1 个答案: