Question

我是AutoIt的新手，我的意思是今天新的，我在Koda表单设计器中创建一个GUI。我想弄清楚如何保存表单中的所有输入部分，所以如果有人要再次打开它，它将有他们保存的输入。

干杯

Answer 1

AutoIt使用的最简单的文件格式是ini文件。您之前可能已经将这些视为程序的配置文件，Windows曾经将它们用于所有程序。

以下功能非常重要：IniRead，IniWrite，GUICtrlRead，GUICtrlSetData。

其他类型的输入略有不同。复选框需要稍微不同的代码，当使用多行编辑控件时，您可以使用几个技巧来解决ini限制。

在最基本的情况下，这是一个koda生成的表单，添加了几行：

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $sConfigPath = @ScriptDir & "\MySettings.ini"

#Region ### START Koda GUI section ### Form=
Local $Form1 = GUICreate("Form1", 362, 34, 192, 124)
Local $Input1 = GUICtrlCreateInput("", 8, 8, 346, 20)
#EndRegion ### END Koda GUI section ###

; Here we can execute code before the window is shown

; Get the value of Input1 from the ini file.
GUICtrlSetData($Input1, IniRead($sConfigPath, "inputs", "Input1", ""))

; Show the window afterwards so it looks a bit tidier
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            ; Note: Exit needs to be changed to ExitLoop
            ; for any code after the loop to execute.
            ExitLoop
    EndSwitch
WEnd

; This code will be executed when the window is closed.

; Writes the value of the $Input1 control to the ini file
IniWrite($sConfigPath, "inputs", "Input1", GUICtrlRead($Input1))

该模式适用于只需要从代码中的单个位置加载和保存的简单表单。当您制作更复杂的GUI时，您将要更改加载和保存输入到函数，这将允许您使用正常的应用，取消和确定按钮甚至按钮重置为默认值

最后需要注意的是，值得注意的是，基于stackoverflow的AutoIt用户非常小。我们的大部分社区都在AutoIt forums。像这样的问题通常会在10分钟内得到答案，相比之下，这里会有几个小时。

如何在Koda For Designer中保存输入

1 个答案: