如何让我的mac终端对我的bash脚本进行颜色编码？

Question

所以我只是想知道是否有可能让我的mac显示我的bash脚本的颜色，以便更容易看到轻微的错误，什么不是。像在java中一样

scan.nextInt();

Eclipse（一个编写代码的程序）将使Int变为红色。这就是我想要的东西。只是为了更容易看到我的代码。我甚至不知道这是否可能，所以感谢所有愿意提供建议的人。

其他一些信息：我的MacBook版本为10.8.5

Answer 1

显然在bash（mac默认shell）中是不可能的。您可以使用fish shell或zsh（我个人选择）与zsh-syntax-highlighting。

如果您选择zsh，我强烈推荐oh-my-zsh框架。

Answer 2

你知道吗？安装MacVIM。 MacVIM内置了语法高亮显示功能。顺便说一句，Mac上已有的vim命令也是如此。最有可能的是，您需要设置.vimrc文件才能为您启用语法突出显示。

我不太确定从何处获取此信息，但这是一个.vimrc文件，可为您启用语法高亮显示：

" An example for a vimrc file.
"
" Maintainer:       Bram Moolenaar <Bram@vim.org>
" Last change:      2002 Sep 19
"
" To use it, copy it to
"     for Unix and OS/2:  ~/.vimrc
"         for Amiga:  s:.vimrc
"  for MS-DOS and Win32:  $VIM\_vimrc
"       for OpenVMS:  sys$login:.vimrc

" When started as "evim", evim.vim will already have done these settings.
if v:progname =~? "evim"
  finish
endif

" Use Vim settings, rather then Vi settings (much better!).
" This must be first, because it changes other options as a side effect.
set nocompatible

" allow backspacing over everything in insert mode
set backspace=indent,eol,start

if has("vms")
  set nobackup              " do not keep a backup file, use versions instead
else
  set backup                " keep a backup file
endif
set history=50              " keep 50 lines of command line history
set ruler           " show the cursor position all the time
set showcmd         " display incomplete commands
set incsearch               " do incremental searching

" For Win32 GUI: remove 't' flag from 'guioptions': no tearoff menu entries
" let &guioptions = substitute(&guioptions, "t", "", "g")

" Don't use Ex mode, use Q for formatting
map Q gq

" This is an alternative that also works in block mode, but the deleted
" text is lost and it only works for putting the current register.
"vnoremap p "_dp

" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
  syntax on
   set hlsearch
endif

" Only do this part when compiled with support for autocommands.
if has("autocmd")

  " Enable file type detection.
  " Use the default filetype settings, so that mail gets 'tw' set to 72,
  " 'cindent' is on in C files, etc.
  " Also load indent files, to automatically do language-dependent indenting.
  filetype plugin indent on

  " Put these in an autocmd group, so that we can delete them easily.
  augroup vimrcEx
  au!

  " For all text files set 'textwidth' to 78 characters.
  autocmd FileType text setlocal textwidth=78

  " When editing a file, always jump to the last known cursor position.
  " Don't do it when the position is invalid or when inside an event handler
  " (happens when dropping a file on gvim).
  autocmd BufReadPost *
    \ if line("'\"") > 0 && line("'\"") <= line("$") |
    \   exe "normal g`\"" |
    \ endif

  augroup END

else

  set autoindent            " always set autoindenting on

endif " has("autocmd")
syntax on
set ai showmode showmatch report=1 sw=4 showcmd textmode ruler smartindent nobackup nohlsearch ff=unix diffopt+=iwhite

Answer 3

安装pygmentize sudo easy_install Pygments，然后运行pygmentize script.sh：

更多例子：

pygmentize -l sh ~/.bashrc
pygmentize -L # list lexers, formatters, filters, and styles
pygmentize -H formatter terminal # help for the terminal formatter
pygmentize -f html -O full,style=emacs -o out.html file.rb
for f in **/*.rb;do printf "%-$COLUMNS"s $f|tr ' ' -;pygmentize $f;done