Question

据我所知，根据数学舍入，当舍入数为5时，应该如下工作。

2.435 => 2.44 (Round Up, if rounding to digit(3) is odd number)
2.445 => 2.44 (Round Down, if rounding to digit(4) is even number)

如果我们总结得很好，

2.435 + 2.445 =  4.88
2.44 + 2.44 = 4.88

我非常肯定在.Net中还可以完成这样的工作。

但是在SQL服务器中，5总是向上舍入，根据数学不正确。

SELECT round(2.345, 2)  = 2.35
SELECT round(2.335, 2) => 2.34

这导致四舍五入值总和的1美分差异。

2.345 + 2.335 = 4.68
2.35 + 2.34 = 4.69 => which is not correct

我已尝试使用十进制和货币数据类型。

我做错了吗？有解决方法吗？

Answer 1

您正在寻找 Banker的Rounding - 这是C＃中的默认舍入，但不是SQL Server ROUND（）的工作方式。

请参阅Why does TSQL on Sql Server 2000 round decimals inconsistently?以及http://blogs.lessthandot.com/index.php/DataMgmt/DataDesign/sql-server-rounding-methods和http://www.chrispoulter.com/blog/post/rounding-decimals-using-net-and-t-sql

Answer 2

如果您确实想在SQL Server中使用银行家的四舍五入...

CREATE FUNCTION BankersRounding(@value decimal(36,11), @significantDigits INT)        
RETURNS MONEY        
AS        
BEGIN        
    -- if value = 12.345 and signficantDigits = 2...        

    -- base = 1000        
    declare @base int = power(10, @significantDigits + 1)        


    -- roundingValue = 12345        
    declare @roundingValue decimal(36,11) = floor(abs(@value) * @base)        
    -- roundingDigit = 5        
    declare @roundingDigit int = @roundingValue % 10        

    -- significantValue = 1234        
    declare @significantValue decimal(36,11) = floor(@roundingValue / 10)        
    -- lastSignificantDigit = 4        
    declare @lastSignificantDigit int = @significantValue % 10        


    -- awayFromZero = 12.35        
    declare @awayFromZero money = (@significantValue + 1) / (@base / 10)        
    -- towardsZero = 12.34        
    declare @towardsZero money = @significantValue / (@base / 10)        

    -- negative values handled slightly different        
    if @value < 0        
    begin        
        -- awayFromZero = -12.35        
        set @awayFromZero = ((-1 * @significantValue) - 1) / (@base / 10)        
        -- towardsZero = -12.34        
        set @towardsZero = (-1 * @significantValue) / (@base / 10)        
    end        

    -- default to towards zero (i.e. assume thousandths digit is 0-4)        
    declare @rv money = @towardsZero        
    if @roundingDigit > 5        
        set @rv = @awayFromZero  -- 5-9 goes away from 0        
    else if @roundingDigit = 5         
    begin        
        -- 5 goes to nearest even number (towards zero if even, away from zero if odd)        
        set @rv = case when @lastSignificantDigit % 2 = 0 then @towardsZero else @awayFromZero end        
    end        

    return @rv        

end

Answer 3

在5处数学上舍入是正确的，也是基本数学中最常用的舍入类型。其他类型的舍入也是有效的，但不是基本的数学，但更常用于某些领域，因为0.5通常是争议编号。

你所谓的数学四舍五入实际上是银行家四舍五入，这是金融业务中使用的舍入类型。

SQL Server Rounding Issue有5个

3 个答案: