Question

我正在研究连续多次调用子程序（进而执行迭代）的代码。我想并行化子程序内的迭代。 mpi的问题是我只允许初始化一次。因此，我不能在我的子程序中初始化它，它被多次调用。任何人都可以提出一个解决方法吗？

我的问题大致如下所述：

program p

...

do i=1,10000
    call subroutine s(i)
end do

end program p

subroutine s(j)  

...

do i=1,10000
    ...
end do

end subroutine s

我希望将此过程并行化。

非常感谢。这有帮助！但让我重新提出我的问题，在主程序的迭代中，连同子程序s，我必须调用另一个子程序s2（它不需要并行化）。我想，可以这样做：

  !initialize mpi

  do i=1:1000

  if rank!=0

  call s

  else call s2

  end if

  end do

  !finalize mpi

但这里的主要问题是，当其余流程进展缓慢时，流程0将快速进行。（不可取的东西）。那么，是否有可能在每次迭代后让进程0等待，直到另一个进程完成迭代？

Answer 1

您需要在主程序中初始化并完成MPI。通常，您可以定义对子例程中的工作有效的负载平衡。

然后在子程序中并行执行循环并在子程序结束时收集（减少？）结果，这样就可以获得下次调用子程序时所需的所有信息。

这与在主程序中使用循环的方式相同（不调用子例程）。

这是一个最低限度的例子：

module testMod
  use mpi
  implicit none
!#include "mpif.h"
!===
contains
!===
  subroutine s(mysize, myrank, array)
    integer,intent(in)    :: mysize, myrank
    integer,intent(inout) :: array(:)
    integer               :: i, ierror

    ! Do stuff
    do i=1,size(array)
      ! Skip element that is not associated with the current process
      if ( mod(i,mysize) .ne. myrank ) cycle
      array(i) = array(i) + 1
    enddo ! i

    ! MPI Allreduce
    call MPI_Allreduce(MPI_IN_PLACE, array, size(array), MPI_INTEGER, &
                       MPI_MAX, MPI_COMM_WORLD, ierror)
  end subroutine
end module

program mpiTest
  use testMod
  use mpi
  implicit none
!#include "mpif.h"

  integer :: mysize, myrank, ierror
  integer,parameter    :: ITER=100
  integer,parameter    :: arraySize=10
  integer :: work(arraySize)
  integer :: i

  ! MPI Initialization
  call MPI_Init(ierror)
  call MPI_Comm_rank(MPI_COMM_WORLD, myrank, ierror)
  call MPI_Comm_size(MPI_COMM_WORLD, mysize, ierror)

  work = 0
  do i=1,ITER
    call s(mysize, myrank, work)
  enddo

  if ( myrank .eq. 0 ) write(*,*) work

  ! MPI Finalize
  call MPI_Finalize(ierror)

end program

在子程序中使用MPI

1 个答案: