Question

我有一个后台线程向主线程发送消息，而后者又将消息添加到TListBox中，就像日志一样。

事实上，这个后台线程非常快，我真的不需要快速更新日志。我想将消息添加到TStringList并设置一个计时器来每隔一秒左右更新一次TListBox。

我尝试过使用：

listBox1.Items := StringList1;

或

listBox1.Items.Assign(StringList1);

在OnTimer事件中

它可以工作。事实是，它永远不会让用户真正滚动或点击列表框，因为它每秒刷新一次。

我正在使用Delphi XE4

是否有更优雅的方式将列表框的内容与此背景StringList（或必要时的任何其他列表）同步？提前谢谢！

Answer 1

使用虚拟方法

将ListBox的Style属性设置为lbVirtual，并指定OnData事件，让它请求绘制控件所需的字符串，而不是拥有重置字符串的字符串完全控制每一次更新。说明性代码：

unit Unit1;

interface

uses
  Windows, Messages, Classes, Controls, Forms, AppEvnts, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    ApplicationEvents1: TApplicationEvents;
    ListBox1: TListBox;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ListBox1Data(Control: TWinControl; Index: Integer;
      var Data: String);
    procedure ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
    procedure Timer1Timer(Sender: TObject);
  private
    FStrings: TStringList;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  FStrings := TStringList.Create;
  FStrings.CommaText := 'A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z';
  ListBox1.Count := FStrings.Count;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FStrings.Free;
end;

procedure TForm1.ListBox1Data(Control: TWinControl; Index: Integer;
  var Data: String);
begin
  Data := FStrings[Index];
end;

procedure TForm1.ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
begin
  FStrings[Random(FStrings.Count)] := Chr(65 + Random(26));
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  ListBox1.Invalidate;
end;

end.

在此示例中，我使用OnIdle组件的TApplicationEvents事件来模拟StringList的线程更新。请注意，您现在可以滚动并选择ListBox中的项目，尽管计时器的更新间隔为1秒。

同步项目计数

StringList项目计数的变化也需要反映在ListBox中。这需要由ListBox1.Count := FStrings.Count完成，但ListBox外观将再次重置。因此，需要通过暂时阻止它重新绘制/更新来解决方法：

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if Random(2) = 0 then
  begin
    FStrings.Add('A');
    SyncListCounts;
  end
  else
    ListBox1.Invalidate;
end;

procedure TForm1.SyncListCounts;
var
  SaveItemIndex: Integer;
  SaveTopIndex: Integer;
begin
  ListBox1.Items.BeginUpdate;
  try
    SaveItemIndex := ListBox1.ItemIndex;
    SaveTopIndex := ListBox1.TopIndex;
    ListBox1.Count := FStrings.Count;
    ListBox1.ItemIndex := SaveItemIndex;
    ListBox1.TopIndex := SaveTopIndex;
  finally
    ListBox1.Items.EndUpdate;
  end;
end;

TListBox与TStringList同步

1 个答案:

使用虚拟方法

同步项目计数