Question

我有无框架主窗口，由我的main.qml文件中的qml（ApplicationWindow {..}）创建我通过QQmlApplicationEngine::load实例化qml（Qt5.1中引入的类）。如果我设置Qt.FramelessWindowHint标志，则窗口是无框架的，但是会丢失阴影（在Windows中）。如何在我的窗口添加阴影？

我的窗口列表：

ApplicationWindow {
    id: rootWindow
    color : "#f8f8f8"
    maximumHeight: 445
    minimumHeight: 445
    minimumWidth: 730
    maximumWidth: 730
    flags  : Qt.FramelessWindowHint  |  Qt.Window

    Component.onCompleted: {
        setHeight(455)
        setWidth(740)
    }

    MainObject{
            id:mainObject1
            anchors.fill: parent
            height:445
            width:730
    }


}

Answer 1

解决方案是实现应用程序不可或缺的阴影部分，这样你就可以禁用WM装饰并且仍然有装饰，并且在不同的平台上保持一致。

在下面的示例中，窗口有一个阴影，甚至可以动画来创建移动窗口时抬起窗口的效果。当窗口最大化时，边距将被移除，因此阴影不再可见。

import QtQuick 2.7
import QtQuick.Controls 2.1
import QtGraphicalEffects 1.0
import QtQuick.Window 2.3

ApplicationWindow {
    id: main
    visible: true
    width: 300
    height: 200
    color: "#00000000"
    flags: Qt.FramelessWindowHint | Qt.Window

    Rectangle {
      id: rect
      anchors.fill: parent
      anchors.margins: main.visibility === Window.FullScreen ? 0 : 10
      MouseArea {
        id: ma
        anchors.fill: parent
        property int dx
        property int dy
        onPressed: { dx = mouseX; dy = mouseY }
        onPositionChanged: {
          main.x += mouseX - dx
          main.y += mouseY - dy
        }
        onDoubleClicked: main.visibility = main.visibility === Window.FullScreen ? Window.AutomaticVisibility : Window.FullScreen
      }
    }

    DropShadow {
      anchors.fill: rect
      horizontalOffset: 1
      verticalOffset: 1
      radius: ma.pressed ? 8 : 5
      samples: 10
      source: rect
      color: "black"
      Behavior on radius { PropertyAnimation { duration: 100 } }
    }
}

Answer 2

如果你的意思是阴影效果，那就不一定了。

除了您刚刚使用的无框窗口标志外，我们无法控制Qt中的WM装饰。这几乎是特定于WM的。 Windows（TM）WM应用阴影效果来装饰窗口，但这是Windows（TM）的选择。此外，您刚刚暗示它不应该装饰。

qml无框窗口的阴影

2 个答案: