Question

下面是我的excel函数输入，但它似乎没有工作，因为它只是返回 - 在谷歌文档。

=IF(ISERROR(VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE)),
    VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE),
    VLOOKUP(F11,Formulas!C2:D17, 2, FALSE))

以下是我想要进行vlookup的信息。

               A    B    C   D

      1       NYJ   27  PHI 20
      2       BUF   13  DET 35
      3       CIN   27  IND 10
      4       MIA   24  NO  21
      5        TB   12  WAS 30
      6       CAR   25  PIT 10
      7       ATL   16  JAC 20
      8        NE   28  NYG 20
      9       MIN   24  TEN 23
      10      STL   24  BAL 21
      11      CHI   16  CLE 18
      12       KC   30  GB  8
      13      DAL   6   HOU 24
      14      DEN   24  ARI 32
      15       SD   6   SF  41
      16      SEA   22  OAK 6

假设用户在单元格F11中输入“GB”。公式的要点是将点插入GB的右侧。公式应该在第一列中查找GB。如果它为TRUE，它将为第一列执行vlookup，因为它在第一列中找到了GB。如果它是FALSE，它将为第3列进行vlookup。

不确定发生了什么？仅供我使用“TRUE”和“FALSE”替换公式中的最后两个vlookup函数，它可以正常工作。这只是一个谷歌文档问题吗？

任何帮助都会很棒！感谢

更新

我在excel中尝试了这个并获得＃N / A

Answer 1

当您返回号码时，此处的替代方案可能是使用SUMIF，即

=SUMIF(Formulas!A:C,F11,Formulas!B:D)

如果找不到F11，你将获得零

Answer 2

使用IFERROR代替ISERROR：

=IFERROR(VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE),VLOOKUP(F11,Formulas!C2:D17, 2, FALSE))

Answer 3

您的公式将始终使用您当前的数据返回#N/A。您的VLOOKUP很好，但问题出在IF上。让我解释一下：

我们打电话给VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE)函数F1和VLOOKUP(F11,Formulas!C2:D17, 2, FALSE) F2。

您的IF公式为：

=IF(ISERROR(F1),F1,F2)

字面含义：如果F1返回错误，请使用F1！如果F1没有返回错误，请使用F2（顺便说一句，现在会返回错误）。

这有意义吗？试着转过身来：

=IF(ISERROR(VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE)),
VLOOKUP(F11,Formulas!C2:D17, 2, FALSE),
VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE))

现在应该可以了。您还可以使用IFERROR来缩短它，因为您正在重复两个操作：

=IFERROR(VLOOKUP(F11,Formulas!$A2:$B17, 2, FALSE),VLOOKUP(F11,Formulas!C2:D17, 2, FALSE))

现在意味着如果F1出错，请使用F2，否则，使用F1本身。

Google Docs VLOOKUP ISERROR IF功能

3 个答案: