Question

我是XSL的新手，很明显，一些非常基本的东西让我很难过。假设我有一个XML文档，如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<essay><author>John Stamos</author>
<text>
    <p>In his song "Turn! Turn! Turn!," Bob Dylan quotes the Bible:
    <quotation>"To every thing there is a season, and a time to every purpose under the 
    heaven,"</quotation> which is a well-known quotation from Ecclesiastes.
    </p>
</text>
</essay>

就我目前的目的而言，我想在<p>元素和<quotation>元素中标记文本，并仅打印这些文本。 IE，我想要输出

    <span id="paragraph">In his song "Turn! Turn! Turn!," Bob Dylan quotes the Bible:
    <span id="quotation">"To every thing there is a season, and a time to every purpose under the 
    heaven,"</span> which is a well-known quotation from Ecclesiastes.</span>

但是，当我使用如下的样式表时，我遇到了麻烦：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-    
c.org/ns/1.0"
version="1.0">

<xsl:template match="/">
    <xsl:apply-templates select="//text"/>
</xsl:template>

<xsl:template match="p">
    <span id="paragraph"><xsl:value-of select="//p"/></span>
</xsl:template>

<xsl:template match="quotation">
    <span id="quotation"><xsl:value-of select="//quotation"/></span>
</xsl:template>

</xsl:stylesheet>

引用模板永远不会被调用; p，它的父母，显然优先。我该怎么做？

Answer 1

引用模板永远不会被调用的原因是因为您没有告诉XSLT在匹配 p 的模板中继续处理。您所做的就是输出一个元素，因此XSLT处理器不会继续为 p 元素的任何后代进行任何模板匹配。您需要做的是将此行添加到模板中（在 span 元素内），以便XSLT可以继续并匹配引用元素。

<xsl:apply-templates />

事实上，你也遇到了这条线的问题

<xsl:value-of select="//p"/>

这实际上将返回文档中第一个 p 元素下的所有文本，而不一定是您所在的文本。您可以将其更改为：

 <xsl:value-of select="."/>

但是这将包括嵌套引用元素中的任何文本。但是，在这种情况下，你根本不需要这个 xsl：value-of ，因为XSLT具有内置模板的概念，它将输出它找到的任何文本节点的文本，所以只需执行 xsl：apply-templates 即可。

试试这个XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:template match="/">
    <xsl:apply-templates select="//text"/>
</xsl:template>

<xsl:template match="p">
    <span id="paragraph"><xsl:apply-templates /></span>
</xsl:template>

<xsl:template match="quotation">
    <span id="quotation"><xsl:apply-templates /></span>
</xsl:template>

</xsl:stylesheet>

在XSLT中标记或修改子节点

1 个答案: