Question

开始我是一个菜鸟。我昨天第一次看到了VBA。如果你愚蠢的答复，我很感激。大声笑。

每周几次，我会在工作时获得电子表格。我必须拆分邮政编码并将它们移到那里的透视商店。有大约20个邮政编码，虽然我使用排序选项，它仍然需要我一段时间。我想使用marco几乎给每个邮政编码一个商店。

这是我的问题。我试图看看“J1”如果邮政编码与许多我希望“Bullhead”写成“M1”中的一个匹配

我能够做到这一点，我花了几个小时的反复试验才得出最好的结果。我尝试了很多不同的东西。（最底层是我提出的）

这是问题所在。我需要在电子表格中一直这样做。即。如果m3 = 86409 J3 =金曼。如果m4 = 86409 j4 =金曼。所以一直到M5000，J5000。

非常感谢任何帮助。我想做的很简单，但我自己找不到答案，或者我无法理解。我想我将不得不重新开始。并采取不同的方法。不知道是什么。

Sub MoversBirthdays()  
    Dim zipcode As Long, Store As String  
    zipcode = Range("J2").Value   
    If zipcode = "86426" Or "86427" Or "86429" Or "86430" Or "86435" Or "86436" Or "86437" Or "86438" Or "86439" Or "86440" Or "86442" Or "86446" Or "89028" Or "89029" Or "89046" Or "92304" Or "92332" Or "92363" Then Store = "Bullhead" Else: Store = "Kingman"  
    If zipcode = "" Then Store = ""  
    Range("M2").Value = Store  
End Sub

Answer 1

Sub MoversBirthdays()

    Dim varZip As Variant
    Dim arrStore() As String
    Dim StoreIndex As Long

    With Range("J2", Cells(Rows.Count, "J").End(xlUp))
        If .Row < 2 Then Exit Sub   'No data
        ReDim arrStore(1 To .Rows.Count)
        For Each varZip In .Value
            StoreIndex = StoreIndex + 1
            Select Case varZip
                Case 86426 To 86427, 86429 To 86430, 86435 To 86440, 86442, 86446, 89028 To 89029, 89046, 92304, 92332, 92363
                    arrStore(StoreIndex) = "Bullhead"
                Case ""
                    arrStore(StoreIndex) = ""
                Case Else
                    arrStore(StoreIndex) = "Kingman"
            End Select
        Next varZip
    End With

    If StoreIndex > 0 Then Range("M2").Resize(StoreIndex).Value = Application.Transpose(arrStore)

End Sub

Answer 2

您的代码存在一些问题。

首先，您将zipcode定义为Long，但将其与字符串进行比较。它应该被定义为一个String（或与Longs相比）。

其次，你不能用一个值列表来做一个If。它解析，但它被解释为If zipcode is 86426; Or If 86427; Or If 86429...。你实际上需要为每个拉链说If zipcode = "xxx"。

但是，由于您使用的是Excel，因此您可以将拉链列表放在工作表上，并将其引用以进行比较。假设列表位于A列中，以下代码将执行您所需的操作：

Sub MoversBirthdays2()
    Dim zipcode As String, Store As String
    Dim c As Range
    For Each c In Range("j2:j5000")
        zipcode = c.Value

        If zipcode = "" Then
            Store = ""
        Else
            If WorksheetFunction.CountIf(Range("a:a"), zipcode) > 0 Then
                Store = "Bullhead"
            Else
                Store = "Kingman"
            End If
        End If
        c.Offset(0, 2) = Store
    Next
End Sub

如果你实际上不需要用空白覆盖列M中的值，如果zip是空白的，那么它可以更简单一点：

Sub MoversBirthdays2()
    Dim zipcode As String, Store As String
    Dim c As Range
    For Each c In Range("j2:j5000")
        zipcode = c.Value

        If zipcode <> "" Then
            If WorksheetFunction.CountIf(Range("a:a"), zipcode) > 0 Then
                Store = "Bullhead"
            Else
                Store = "Kingman"
            End If
            c.Offset(0, 2) = Store
        End If
    Next
End Sub

如何在Excel中编写VBA多行对应单元格

2 个答案: