Question

我们将XSL样式表应用于许多具有不同结构和标记的XML文件。我们希望对我们的所有文件使用单个XSL样式表，如果添加了具有新内容结构的XML文件，我们可以简单地添加新的xpath。

（我可能会补充一点，这是用于Apache的Solr，输出文档需要以某种方式查看。）

到目前为止，我们已经设法编写了复制各种字段的代码，如下所示：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xalan="http://xml.apache.org/xslt" xmlns:exslt="http://exslt.org/common" version="1.0">
<xsl:output method="xml" encoding="UTF-8" indent="yes" xalan:indent-amount="4" omit-xml-declaration="yes"/>
<xsl:template match="/">
    <xsl:param name="fileName" />
    <xsl:param name="fileURI" />
    <xsl:param name="timeCreatedLong" />
<add>
    <doc>
        <!-- REQUIRED FIELDS. DO NOT CHANGE -->
            <field name="fileName"><xsl:value-of select="$fileName" /></field>
            <field name="fileURI"><xsl:value-of select="$fileURI" /></field>
            <field name="timeCreatedLong"><xsl:value-of select="$timeCreatedLong" /></field>
        <!-- //END OF REQUIRED FIELDS -->

        <!-- DSV INTERNAL XML -->
            <!-- Consignment Identifiers -->
            <field name="consignmentIdentifiers"><xsl:value-of select="//consignmentlist/consignment/consignmentId" /></field>
            <field name="consignmentIdentifiers"><xsl:value-of select="//consignmentlist/consignment/references/reference[@type = 'consignment_number']/value" /></field>
            <!-- //Consignment Identifiers -->

            <!-- Transport company information -->
            <field name="carrier"><xsl:value-of select="//transport/transportservice/carriername" /></field>
            <field name="carrierService"><xsl:value-of select="//transport/transportservice/carrierservicename" /></field>
            <field name="transportMode"><xsl:value-of select="//transport/transportservice/transportmode" /></field>
            <!-- //Transport company information -->
        <!-- //DSV INTERNAL XML -->



        <!-- POSTEN NORDIC LOGISTICS ORDER.XML -->
            <!-- Consignment Identifiers -->
            <field name="consignmentIdentifiers"><xsl:value-of select="//TransportJob/Consignment/@consignmentId" /></field>
            <!-- //Consignment Identifiers -->

            <!-- Transport company information -->
            <field name="definedBy"><xsl:value-of select="//TransportJob/@definedBy" /></field>
            <field name="carrier"><xsl:value-of select="//TransportJob/@profile" /></field>
            <!-- //Transport company information -->
        <!-- //POSTEN NORDIC LOGISTICS ORDER.XML -->
    </doc>
</add>
</xsl:template>

</xsl:stylesheet>

输出取决于处理的文件结构，如下所示：

<add>
<doc>
    <field name="fileName">00373323993931432015_BOOKING.INTERNALXML</field>
    <field name="fileURI">/usr/dropbox/Dropbox/shared/file-search/00373323993931432015_BOOKING.INTERNALXML</field>
    <field name="timeCreatedLong">1377507872000</field>
    <field name="consignmentIdentifiers"/>
    <field name="consignmentIdentifiers">00373323993931432015</field>
    <field name="carrier">DSV</field>
    <field name="carrierService">DSV Mypack</field>
    <field name="transportMode">ROAD</field>
    <field name="consignmentIdentifiers"/>
    <field name="definedBy"/>
    <field name="carrier"/>
</doc>
</add>

如您所见，我们有一些空/自闭元素，我们希望在将它发送到Solr服务器之前将其删除。

所以真正的问题是，在将XSL应用到它之后，有没有办法删除生成的空标签？如上所述，我们希望在同一个XSL文件中完成此操作。

由于

Answer 1

一个改进方法的建议是让一些通用模板匹配元素或属性，但是可以将一个参数设置为您想要输出的字段的“名称”。

第一个模板实际上会输出字段元素，相应地设置名称属性

<xsl:template match="*|@*">
    <xsl:param name="fieldName" />
    <field name="{$fieldName}">
       <xsl:value-of select="." />
    </field>
</xsl:template>

另一个用于忽略没有值的元素或属性：

<xsl:template match="*[normalize-space()='']|@*[normalize-space()='']" />

（注意，更具体的模板（Xpath表达式检查空字符串的模板）将优先于非特定模板。）

然后，而不是写这个：

<field name="consignmentIdentifiers">
    <xsl:value-of select="//consignmentlist/consignment/consignmentId" />
</field>

你会写这个

<xsl:apply-templates select="//consignmentlist/consignment/consignmentId">
    <xsl:with-param name="fieldName" select="'consignmentIdentifiers'" />
</xsl:apply-templates>

与您希望输出的所有其他字段类似。因此，您不必担心在每个语句周围编写 xsl：if 语句。这只是你现在正在做的一点点改变。

编辑：如果您真的想将XSLT应用于自己的输出......

然后，这样做的方法是使用'双程转换'。理想情况下，你可以在这里使用两个XSLT，但是如果你想做一个，那么一个是“第一次传递”而不是简单地输出新元素，你将现有代码包装在一个变量中

<xsl:variable name="HereBeDragons">
   <add>
      <doc>
          <field ...
      </doc>
   </add>
</xsl:variable>

因此，您现在拥有一个包含当前输出的变量，并带有空标记。现在，如果你使用的是XSLT 2.0，你可以这样做，开始寻找变量中元素的模板匹配

<xsl:apply-templates select="$HereBeDragons/*"/>

但是在XSLT 1.0中，您可能会得到一条关于它不是节点集的消息。在XSLT 1.0中，变量实际上存储了“结果树片段”，需要转换为节点集以允许使用模板。看起来你在这里使用EXSLT，所以你应该能够做到这一点，在这种情况下

<xsl:apply-templates select="exslt:node-set($HereBeDragons)/*" />

现在，开始在变量上应用模板，您只需添加模板即可根据需要处理数据。您将拥有一个用于缩进模板的模板

 <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
   </xsl:copy>
 </xsl:template>

另一个，忽略你的空场

<xsl:template match="field[normalize-space()='']" />

但要小心，这些模板适用于第一遍和第二遍。如果您希望模板与第二遍中表现不同的特定元素相匹配，则可能需要使用模板上的模式属性来区分它们。

当然，以这种方式进行两遍变换在内存或速度方面效率都不高，这就是为什么在原始XSLT中添加逻辑以便不首先输出空标记的原因。

Answer 2

您可以在XSLT中添加只在源不为空时才创建元素的检查。例如，您可以执行以下字段carrier：

<xsl:if test="not(//transport/transportservice/carriername='')">
 <field name="carrier">
   <xsl:value-of select="//transport/transportservice/carriername" />
 </field>   
</xsl:if>

如果你这样做，你的输出中就不会出现空字段。

祝你好运，彼得

编辑：如果你想检查输出，使用identity-rule有一种非常有效的方法：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="field[normalize-space()='']"/>

Answer 3

假设XSLT 2.0（你还没有说过），我会这样做：

<xsl:sequence select="
   f:field('carrier', //transport/transportservice/carriername),
   f:field('carrierService', //transport/transportservice/carrierservicename),
   f:field('transportMode', //transport/transportservice/transportmode),
   ..."/>

将f：字段定义为

<xsl:function name="f:field" as="element(field)?">
  <xsl:param name="name" as="xs:string"/>
  <xsl:param name="value" as="xs:string?"/>
  <xsl:if test="$value">
    <field name="{$name}">
      <xsl:value-of select="$value"/>
    </field>
  </xsl:if>
</xsl:function>

将XSLT样式表应用于它自己的输出（过滤掉空元素）

3 个答案: