如何在gnuplot中定义列堆叠直方图的填充颜色

Question

如何更改列堆叠直方图的填充颜色？我的数据如下：

xticlabel_1 xticlabel_2 xticlabel_3
10 20 15

和我的剧本：

set datafile separator "\t"
set term postscript colour solid
set size 1,0.5
set output 'duplication_stats.eps'
set style data histograms
set style histogram columnstacked
set boxwidth 0.5
set style fill solid border -1
set tics scale 0.0
set ytics
set xtics rotate by -20
#
plot 'duplication_stats' using 2 ti col lc rgb "grey"

1. 如果我删除“columnstacked”，则xtic标签消失，但绘制的直方图条是灰色的，如预期的那样。

2. 如果使用“columnstacked”，则直方图栏为红色，并且忽略“lc rgb gray”。

我希望同时拥有 - （1）第一行的xtic标签和（2）从不同列绘制的直方图条的不同颜色。

你知道怎么做吗？

非常感谢你。

Answer 1

对于columnstacked直方图，一行的所有条目都用相同的颜色绘制，下一行用另一种颜色。主要是您可以使用newhistogram每次设置另一种颜色，并在at <xpos>之后使用newhistogram进行手动定位。

set term postscript colour solid
set size 1,0.5
set output 'duplication_stats.eps'
set style data histograms
set style histogram columnstacked
set boxwidth 0.5
set style fill solid 1.00 noborder
set tics scale 0.0
set ytics
set xtics rotate by -20
#
plot 'duplication_stats' u 1 lt 1 title columnhead,\
     newhistogram lt 2 at 1, '' u 2 ti col,\
     newhistogram lt 3 at 2, '' u 3 ti col

这给了我：

请注意，这仅适用于gnuplot 4.6 patchlevel 1，4.6.0无效。