Question

我刚刚使用cmake作为构建系统启动了一个Qt5项目。到目前为止，这工作得很好，但我有一个问题，我想从qrc文件加载一个图标。

项目结构：

CMakeLists.txt
-- icons/
   CMakeLists.txt
   icons.qrc
   locked.png
-- src/
   CMakeLists.txt
   source files...

顶级CMakeLists.txt：

cmake_minimum_required(VERSION 2.8.11) #2.8.11 provides an easy way to build with qt5
project(fluchOmat)

# Find includes in corresponding build directories
set(CMAKE_INCLUDE_CURRENT_DIR ON)
# Instruct CMake to run moc automatically when needed.
set(CMAKE_AUTOMOC ON)

# Find the QtWidgets library. This has dependencies on QtGui and QtCore!
find_package(Qt5Widgets REQUIRED)
# Find the QtMultimedia module
find_package(Qt5Multimedia REQUIRED)

add_subdirectory(icons)
add_subdirectory(src)

图标/中的CMakeLists.txt

set(RESOURCE
    ${CMAKE_CURRENT_SOURCE_DIR}/icons.qrc
)

qt5_add_resources(RESOURCE_ADDED ${RESOURCE})

图标/

中的

icons.qrc

<RCC>
    <qresource prefix="/">
        <file alias="locked">locked.png</file>
    </qresource>
</RCC>

src /（重要部分）中的CMakeLists.txt

add_executable(fluchOmat ${SOURCES} ${HEADERS} ${fluchOmat_FORMS} ${RESOURCES_ADDED})

一些示例代码

QPixmap pm(":/locked.png");
qDebug("Width: " + pm.width());

什么都不返回，显然这不起作用。

Qt5和cmake没有太多资源。谁能帮我这个？这是一个cmake问题吗？例如，我不确定qt5_add_resources是否位于正确的位置。我的qrc文件错了吗？

非常感谢任何帮助！

Answer 1

问题在于CMake的范围规则。每个add_subdirectory调用都会创建自己的范围。在这样的子目录中声明的变量不会自动填充到父作用域。

所以问题是虽然RESOURCE_ADDED包含了icons / CMakeLists.txt范围内的有效路径，但它不在根CMakeLists.txt中，因此在您使用时它是一个空变量它在src / CMakeLists.txt。

要在范围内提高变量，可以在icons / CMakeLists.txt中执行以下操作：

qt5_add_resources(RESOURCE_ADDED ${RESOURCE})
set(RESOURCE_ADDED ${RESOURCE_ADDED} PARENT_SCOPE)

现在还有一个小问题了！

虽然这将包含src / CMakeLists.txt中的有效值，但它指向一个尚不存在的文件。 qt5_add_resources函数必须将GENERATED源文件属性应用于变量。此属性不会转发到父作用域中设置的变量。

由于add_executable期望文件默认存在，因此您需要将GENERATED属性重新应用于父作用域中的变量。你可以这样做，例如在src / CMakeLists.txt中，像这样：

set_source_files_properties(${RESOURCE_ADDED} PROPERTIES GENERATED ON)
add_executable(fluchOmat ... ${RESOURCE_ADDED})

我不确定qt5_add_resources是否会添加任何其他属性 - 如果是这样，您可能还需要重新应用这些属性。

我猜想避免这种情况的最简单方法是不使用add_subdirectory(icons)，而只是将所有与Qt相关的CMake代码移到src / CMakeLists.txt：

set(RESOURCE ${CMAKE_SOURCE_DIR}/icons/icons.qrc)
qt5_add_resources(RESOURCE_ADDED ${RESOURCE})
add_executable(fluchOmat ... ${RESOURCE_ADDED})

无法加载Qt5 / cmake Project中Qt资源文件中指定的图像

1 个答案: