Question

我最近升级到XE4，现在正在寻找XE3的更改和所谓的修复。

让我感到惊讶的是，任务栏上按钮的上下文菜单不再出现。

复制非常简单：只需在XE4中创建一个新的Firemonkey项目并在Windows上运行它。右键单击任务栏应用程序按钮，查看上下文菜单是否出现。我的意思是“关闭”，“恢复”，“最小化”等菜单。这仅适用于Windows XP和Server 2003.在Win7上，它可以工作并显示“关闭”菜单项。

按钮的标题现在也不同了。它应该是“Form 1”作为主窗体的标题，而是将Project1作为可执行文件名。这适用于所有Windows版本。

有人可以帮我这个吗？人们仍然使用XP，这种行为对于用户来说是非常意外的。

由于

Answer 1

自从我提出这个问题以来已经过去了一段时间，但我在此期间找到了一个解决方案，并会发布以防万一对其他人有用。

错误的标题和缺少菜单的问题来自于Delphi XE4改变了Firemonkey应用程序的窗口结构这一事实。在此之前，主窗体的窗口放在任务栏上，并具有相应的标题和上下文菜单。在XE4中，应用程序创建一个名为“TFMAppClass”的新窗口，并将其用作放置在任务栏中的主应用程序窗口。主表单窗口是该窗口的兄弟。
这导致无法设置任务栏按钮标题，没有上下文菜单，没有正确响应按钮上的点击，也没有隐藏主窗体隐藏按钮。

因此，需要的是从任务栏隐藏应用程序窗口并显示窗体窗口。但要做到这一次是不够的，因为应用程序窗口的样式在每次最小化/恢复时都会重置，并且会重新出现在任务栏上。

要隐藏应用窗口，只需拨打ShowWindow(AppWindowHandle, SW_HIDE) 要在任务栏上显示主窗体窗口，我们必须使用WS_EX_APPWINDOW设置SetWindowLong()扩展窗口样式，并在每次显示，恢复等应用时调用ShowWindow并将其带到前景。

这是通过放置一个钩子来拦截WM_CREATE，WM_SHOWWINDOW和WM_ACTIVATE消息并在调用这些消息时应用样式来完成的。为了方便使用，所有代码都放在一个单元中，钩子设置在initialization部分。
没有可以调用的函数。要使用该单元，只需将其放在uses子句中的某个位置。

unit FM3TaskbarFix;

interface

implementation

{$IFDEF MSWINDOWS}
uses
  Winapi.Messages, Winapi.Windows, System.Sysutils, Fmx.Forms, Fmx.Platform.Win;

var
  GHookHandle: HHOOK;      // Handle for the hook we set
  GAppWnd    : HWND = 0;   // Handle of the main application window

function CallWndProc(nCode: Integer; iWParam: WPARAM; iLParam: LPARAM): LRESULT; stdcall;
var
  ActiveThreadID, WindowThreadID: DWORD;
  ProcMsg: TCWPStruct;
begin
  Result := CallNextHookEx(GHookHandle, nCode, iWParam, iLParam);

  if (nCode < 0) then
    Exit;

  ProcMsg := PCWPStruct(iLParam)^;

  case ProcMsg.message of
    WM_CREATE:
      // Save the "main" app window handle for later usage. There is only one window with the TFMAppClass class per app
      if (GAppWnd = 0) and (PCREATESTRUCT(ProcMsg.lParam)^.lpszClass = 'TFMAppClass') then
        GAppWnd := ProcMsg.hwnd;

    WM_ACTIVATE, WM_SHOWWINDOW:
    begin
      // Hide the app window. This has to be called on each minimize, restore, etc.
      if IsWindowVisible(GAppWnd) then
        ShowWindow(GAppWnd, SW_HIDE);

      // Only handle Show/Activate. wParam of 1 means the app is shown or activated, NOT hidden or deactivated
      // Also apply the style settings only to the Application.MainForm
      // We don't want to show other forms on the taskbar
      if (ProcMsg.wParam = 1) and
         (GetWindow(ProcMsg.hwnd, GW_OWNER) = GAppWnd) and Assigned(Application.MainForm) and
         (WindowHandleToPlatform(Application.MainForm.Handle).Wnd = ProcMsg.hwnd) then
      begin
        // Show the main form on the taskbar
        SetWindowLong(ProcMsg.hwnd, GWL_EXSTYLE, GetWindowLong(ProcMsg.hwnd, GWL_EXSTYLE) or WS_EX_APPWINDOW);
        ShowWindow(ProcMsg.hwnd, SW_SHOW);

        ActiveThreadID := GetWindowThreadProcessId(GetForegroundWindow, nil);
        WindowThreadID := GetWindowThreadProcessId(ProcMsg.hwnd, nil);
        AttachThreadInput(WindowThreadID, ActiveThreadID, True);
        try
          SetForegroundWindow(ProcMsg.hwnd);
          SetActiveWindow(ProcMsg.hwnd);
        finally
          AttachThreadInput(WindowThreadID, ActiveThreadID, False);
        end;
      end;
    end; { WM_ACTIVATE, WM_SHOWWINDOW }

  end; { case }
end;

initialization
  GHookHandle := SetWindowsHookEx(WH_CALLWNDPROC, CallWndProc, 0, GetCurrentThreadID);

finalization
  UnhookWIndowsHookEx(GHookHandle);

{$ENDIF}

end.

顺便说一下，这段代码基于网上的两个样本。我不知道作者是谁，但我赞同这个想法还有一个问题。当应用程序首次最小化时，应用程序窗口的按钮会暂时重新显示，而不是表单按钮。应用程序恢复或再次最小化后，这种情况不再发生。

在带有FM3的Windows XP中缺少任务栏按钮上下文菜单

1 个答案: