Question

我的输入是一个以制表符分隔的文本文件，在D-M-S中为lat long。我要求输出为十进制度我在PHP中有代码，但计算速度很慢。使用awk可以更快地完成吗？

node    name    id  latitude    longitude   seq
nodex   name1   70  N53-24-31.126   W6-20-46.982    59126
nodex   name2   173 N53-20-28.885   W6-14-52.400    16190X
nodex   name3   173 N53-20-28.885   W6-14-52.400    16191T

我的PHP代码包含公式：

if ($dirLat == 'N') {$signLat = '+';} Else {$signLat = '-';}
if ($dirLat == 'E') {$signLon = '+';} Else {$signLon = '-';}
$latitudeDecimalDeg = $signLat . ($degLat + ($minLat/60) + ($secLat/3600));
$longitudeDecimalDeg = $signLon . ($degLon + ($minLon/60) + ($secLon/3600));

Answer 1

我很确定awk会更快。这可以通过awk轻松完成，使用substr和split拆分每个字段。我把它变成了一个更容易重用的函数：

function dms2deg(s) {
  dir = (substr(s, 1, 1) ~ /^[NE]/) ? 1 : -1
  dms =  substr(s, 2)
  split(dms, arr, "-")
  return dir * (arr[1] + arr[2]/60 + arr[3]/3600)
}

如果您已将上述内容放入 dms2deg 并且数据位于 infile 中，您将使用这样的awk：

awk -f dms2deg -e 'NR>1 { print dms2deg($4), dms2deg($5) }' infile

输出：

53.4086 -6.34638
53.3414 -6.24789
53.3414 -6.24789

或者如果您想要替换现有字段：

awk -f dms2deg -e 'NR>1 { $4 = dms2deg($4); $5 = dms2deg($5) } $1=$1' infile

输出：

node name id latitude longitude seq
nodex name1 70 53.4086 -6.34638 59126
nodex name2 173 53.3414 -6.24789 16190X
nodex name3 173 53.3414 -6.24789 16191T

请注意，这不会保留空白区域，但是column会处理这个问题：

awk -f dms2deg -e 'NR>1 { $4 = dms2deg($4); $5 = dms2deg($5) } $1=$1' infile | column -t

输出：

node   name   id   latitude  longitude  seq
nodex  name1  70   53.4086   -6.34638   59126
nodex  name2  173  53.3414   -6.24789   16190X
nodex  name3  173  53.3414   -6.24789   16191T

Answer 2

我真的不知道它是否会更快，但恕我直言这是你用awk和保持间距的最快方式：

$ cat tst.awk
BEGIN{ FS="[- ]+" }
NR>1 {
    sub( $7"-"$8"-"$9, ($7~/^E/?"+":"-") (substr($7,2) + $8/60 + $9/3600) )
    sub( $4"-"$5"-"$6, ($4~/^N/?"+":"-") (substr($4,2) + $5/60 + $6/3600) )
}
1

$ cat file
node    name    id  latitude    longitude   seq
nodex   name1   70  N53-24-31.126   W6-20-46.982    59126
nodex   name2   173 N53-20-28.885   W6-14-52.400    16190X
nodex   name3   173 N53-20-28.885   W6-14-52.400    16191T

$ awk -f tst.awk file
node    name    id  latitude    longitude   seq
nodex   name1   70  +53.4086   -6.34638    59126
nodex   name2   173 +53.3414   -6.24789    16190X
nodex   name3   173 +53.3414   -6.24789    16191T

我有兴趣知道它是否比PHP脚本更快，所以如果你有机会比较它们，请发布结果。

如果您不关心保留间距，可以使用：

BEGIN{ FS="[- ]+" }
NR == 1 { print; next }
{ print $1, $2, $3, ($4~/^N/?"+":"-") (substr($4,2) + $5/60 + $6/3600), ($7~/^E/?"+":"-") (substr($7,2) + $8/60 + $9/3600), $10 }

Answer 3

awk -F"[- ]+" 'NR==1 {print;next} {s1=($4~/N/)?1:-1;s2=($7~/E/)?1:-1;print $1,$2,$3,s1*(substr($4,2)+$5/60+$6/3600),s2*(substr($7,2)+$8/60+$9/3600),$10}' file

node    name    id  latitude    longitude   seq
nodex name1 70 53.4086 -6.34638 59126
nodex name2 173 53.3414 -6.24789 16190X
nodex name3 173 53.3414 -6.24789 16191T

使用awk将坐标d-m-s转换为十进制度数

3 个答案: