使用一行的gnuplot矩阵或调色板

Question

..大家好。

我想绘制矩阵颜色图（热图）， 但是我想要使用一行打印的数据绘制热图。 我试过了，

p for[i=5:15] 'line' u (i%2):(i/2%10):i+1 w image    

因此gnuplot显示警告图像至少需要2维数据

我的数据集就像这样

0.1(node 1 value at time step 1) 0.1(node 2 "") 0.3(node 3 "") 0.2(node 4 "")   
0.5(node 1 value at time step 2) 1.2(node 2 "") 0.7(node 3 "") 0.2(node 4 "")   
0.8(node 1 value at time step 3) 2.2(node 2 "") 0.1(node 3 "") 0.1(node 4 "")   
0.1(node 1 value at time step 4) 1.2(node 2 "") 1.1(node 3 "") 0.4(node 4 "")   
0.4(node 1 value at time step 5) 1.1(node 2 "") 0.7(node 3 "") 0.6(node 4 "")   
0.3(node 1 value at time step 6) 0.4(node 2 "") 0.2(node 3 "") 0.3(node 4 "")   
0.2(node 1 value at time step 7) 0.3(node 2 "") 0.7(node 3 "") 0.2(node 4 "") 
.
.
.
.

在上面的数据中，一行中有4个值。 在一行中使用4个值，我想制作2X2颜色矩阵 每0.3秒我想改变一条线来制作变色视频。 我可以制作视频，但问题是，如何在一行中使用数据制作矩阵。

我不想转换为x：y：z数据来绘制图像。 我的数据有点长而且重，我担心它会降低速度。 我需要绘制实时热图。 随着价值的变化，颜色也会实时变化

我也试过了调色板，

p for[i=5:15] 'line' u (i%2):(i/2%10):i+1 w p pt 5 ps 23.5 palette

但是，xaxis和yaxis之间存在空白（白色）。

所以，它看起来不太好。

如何使用一行打印的数据绘制热图？

实际上，如果我可以在不保存文件中的数据的情况下绘制实时热图， 会好起来的。 （在C代码中打开gnuplot并将值传递给gnuplot）

提前谢谢

Answer 1

基本上有几种方法可以达到你想要的效果。首先，我展示了将静态数据处理成动画gif的三种可能性：

1. 使用外部工具（此处为awk）处理数据文件一次。

2. （变体1：使用awk等外部工具动态处理数据

3. 仅使用gnuplot

变式1：预处理数据

我认为适合您的数据格式是

N1T1 N2T1
N3T1 N4T1


N1T2 N2T2
N3T2 N4T2
...

请注意数据集之间的两个换行符。有了这个，您可以使用index关键字选择不同的数据集。

要将数据预处理到此文件中，请从gnuplot

调用

system('if [ ! -e dataconv ]; then awk ''{ print $1 " " $2 "\n" $3 " " $4 "\n\n"}'' data > dataconv; fi')

如果您想为所有帧设置固定的颜色范围，您可以使用固定值（如果您知道范围），或者从数据文件中提取它们：

stats 'dataconv' using 1:2
timesteps = int(STATS_records/2)
cbmin = (STATS_min_x > STATS_min_y ? STATS_min_y : STATS_min_x)
cbmax = (STATS_max_x > STATS_max_y ? STATS_max_x : STATS_max_y)
set cbrange[cbmin:cbmax]

现在，为了绘制数据，您最终可以使用matrix并依次选择index的所有时间步骤：

set terminal gif animate delay 30
set output 'animate.gif'
unset key
set xrange[-0.5:1.5]
set yrange[-0.5:1.5]
set xtics 1
set ytics 1
do for [i=0:(timesteps-1)] {
  set title sprintf('time step % 3d', i+1)
  plot 'dataconv' matrix index i with image
}
unset output

在这里，我只显示第一次步骤的结果：

变式2：动态处理数据

您可以使用awk两者来选择时间步长并重新格式化数据。为简单起见，我在这里手动设置固定的颜色范围：

reset
set cbrange[0:3]

set terminal gif animate delay 30
set output 'animate2.gif'
unset key
set xrange[-0.5:1.5]
set yrange[-0.5:1.5]
set xtics 1
set ytics 1
timesteps = int(system('wc -l data | cut -d " " -f1'))
do for [i=0:timesteps] {
  set title sprintf('time step % 3d', i)
  plot '< awk ''{ if (FNR == '.i.') {print $1 " " $2 "\n" $3 " " $4}}'' data' matrix with image
}
unset output

变式3：仅限gnuplot

这只使用gnuplot并且不依赖于任何外部工具，但是更繁琐，因为它需要摆弄using语句。问题是，您有1D数据（只有一行），但想将其绘制为2D，这需要特殊的数据格式才能正常工作。

为了伪造2D输入，我让gnuplot读取两行。当它处理第一行时，gnuplot会记住第3列和第4列的值，并在第1列和第2列的第二行中使用它们。第2行的数据将被丢弃。这有一个小缺点，即除非插入虚拟最后一行，否则不能绘制最后一个时间步。对于4列，估计最大和最小颜色值也有点冗长：

stats 'data' using 1:2 prefix 'A_'
stats 'data' using 3:4 prefix 'B_'
timesteps = int(A_records)
max(x, y) = x > y ? x : y
min(x, y) = x > y ? y : x
cbmin = min(min(A_min_x, A_min_y), min(B_min_x, B_min_y))
cbmax = max(max(A_max_x, A_max_y), max(B_max_x, B_max_y))
set cbrange[cbmin:cbmax]

同样，如果您知道可能的颜色范围，则可以跳过此部分的大部分内容。

set terminal gif animate delay 30
set output 'animate3.gif'
unset key

A0 = 0
A1 = 0
set xrange[0.5:2.5]
set yrange[0.5:2.5]
set xtics 1
set ytics 1

do for [i=0:(timesteps-2)] {
  set title sprintf('time step % 3d', i)
  plot 'data' matrix every :::i::(i+1) \
    using (A0 = ($1 == 2 && $2 == i) ? $3 : A0, \
           A1 = ($1 == 3 && $2 == i) ? $3 : A1, $1+1):\
           ($2-i+1):\
           ($2 == i ? $3 : ($1 == 0 ? A0 : ($1 == 1 ? A1 : $3))) \
           with image
}
unset output

我希望有一种方法可以满足您的需求。

实时绘图

实时绘图的一种可能性是有一个循环，其中绘制了数据文件的最后一行。但是，如果您的程序一次不写完整行，则这对竞争条件是不安全的：

set cbrange[0:3]
unset key
set xrange[-0.5:1.5]
set yrange[-0.5:1.5]
set xtics 1
set ytics 1

while (1) {
  set title "time ".strftime('%T', time(0))
  plot '< tail -1 data | awk ''{print $1 " " $2 "\n" $3 " " $4}'' ' matrix with image
  pause 0.1
}

要中断，只需按Ctrl+C。