Question

我是XSLT 2.0的新手。我对用户定义的函数（<xsl:function）很感兴趣。特别是，我想使用UDF使代码更具模块化和可读性。

我有这个xsl：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet
   version="2.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/">
    <xsl:variable name="stopwords"
        select="document('stopwords.xml')//w/string()"/>
             <wordcount>
                <xsl:for-each-group group-by="." select="
                    for $w in //text()/tokenize(., '\W+')[not(.=$stopwords)] return $w">
                    <xsl:sort select="count(current-group())" order="descending"/>            
                    <word word="{current-grouping-key()}" frequency="{count(current-group())}"/>
                </xsl:for-each-group>
             </wordcount>
</xsl:template>
</xsl:stylesheet>

可以想要添加更多条件测试（例如，排除数字） for $w in //text()/tokenize(., '\W+')[not(.=$stopwords)] 但代码会变得混乱。

如果我将UDF变得更复杂，那么UDF是一个整理该部分代码的选项。这样做是好的做法吗？

Answer 1

那么你可以编写一个在谓词中使用的函数

<xsl:function name="mf:check" as="xs:boolean">
  <xsl:param name="input" as="xs:string"/>
  <xsl:sequence select="not($input = $stopwords) and not(matches($input, '^[0-9]+$'))"/>
</xsl:function>

并在您的代码中使用它，例如

<xsl:stylesheet
   version="2.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:xs="http://www.w3.org/2001/XMLSchema"
   xmlns:mf="http://example.com/mf"
   exclude-result-prefixes="mf xs">
<xsl:output method="xml" indent="yes"/>

    <xsl:function name="mf:check" as="xs:boolean">
      <xsl:param name="input" as="xs:string"/>
      <xsl:sequence select="not($input = $stopwords) and not(matches($input, '^[0-9]+$'))"/>
    </xsl:function>

    <xsl:variable name="stopwords"
        select="document('stopwords.xml')//w/string()"/>

    <xsl:template match="/">
        <wordcount>
            <xsl:for-each-group group-by="." select="
                for $w in //text()/tokenize(., '\W+')[mf:check(.)] return $w">
                <xsl:sort select="count(current-group())" order="descending"/>            
                <word word="{current-grouping-key()}" frequency="{count(current-group())}"/>
            </xsl:for-each-group>
        </wordcount>
    </xsl:template>
</xsl:stylesheet>

XSLT用户定义函数

1 个答案: