Question

我有以下xml和xslt来渲染它，但没有得到任何结果。我一次又一次检查，看到没有路径问题，xsl通过编译器。所以我不确定它是否是命名空间问题或其他什么。很多！

XML文件

<?xml version="1.0" encoding="UTF-8"?>
<bibdataset xsi:schemaLocation="http://www.elsevier.com/xml/ani/ani http://www.elsevier.com/xml/ani/embase_com.xsd" 
xmlns="http://www.elsevier.com/xml/ani/ani" 
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:ce="http://www.elsevier.com/xml/ani/common" 
xmlns:ait="http://www.elsevier.com/xml/ani/ait">
    <item>
        <bibrecord>
            <item-info>
                <itemidlist><ce:doi>10.1258/0268355042555000</ce:doi>
                </itemidlist>
            </item-info>
                <head>
                    <citation-title>
                        <titletext xml:lang="en" original="y">Effect of seasonal variations on the emergence of deep venous thrombosis of the lower extremity
                        </titletext>
                    </citation-title>
                    <abstracts>
                        <abstract xml:lang="en" original="y">
                            <ce:para>Objective: We aimed to determine the role of seasonal and meteorological variations in the incidence of lower extremity
                            </ce:para> 
                        </abstract>
                    </abstracts>
               </head>
         </bibrecord>
    </item>
</bibdataset>

XSLT文件

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.elsevier.com/xml/ani/ani" 
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
    xmlns:ce="http://www.elsevier.com/xml/ani/common" 
    xmlns:ait="http://www.elsevier.com/xml/ani/ait">

  <xsl:output indent="yes" omit-xml-declaration="no"
       media-type="application/xml" encoding="UTF-8" />

  <xsl:template match="/">
    <searchresult>
      <xsl:apply-templates 
        select="/bibdataset/item/bibrecord" />
    </searchresult>
  </xsl:template>

  <xsl:template match="bibrecord">
    <document>
      <title><xsl:value-of select="head/citation-title/titletext" /></title>
      <snippet>
          <xsl:value-of select="head/abstracts/abstract/ce:para" />
      </snippet>
      <url>
        <xsl:variable name="doilink" select="item-info/itemidlist/ce:doi"/>
        <xsl:value-of 
          select="concat('http://dx.doi.org/', $doilink)" />
      </url>
    </document>
  </xsl:template>
</xsl:stylesheet>

Answer 1

这确实是命名空间的问题。在您的XML中，您已声明了一个默认命名空间，表示根元素及其所有后代，以及此命名空间。

<bibdataset .xmlns="http://www.elsevier.com/xml/ani/ani"  ...

现在，在您的XSLT中，您还声明了此命名空间，但没有前缀。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.elsevier.com/xml/ani/ani"

这意味着它仅适用于您输出的元素，因此 searchresult 元素将在此命名空间中输出

<searchresult xmlns="http://www.elsevier.com/xml/ani/ani"

但是，它不适用于XSLT中的xpath表达式，因此这些元素在输入XML中查找没有名称空间的元素。

在XSLT 2.0中，解决方案是简单地声明一个＆＃34; xpath-default-namespace＆＃34;

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.elsevier.com/xml/ani/ani"
    xpath-default-namespace="http://www.elsevier.com/xml/ani/ani" ...

在XSLT 1.0中，您必须使用前缀声明命名空间，并在所有xpath表达式中使用此前缀。

试试这个XSLT

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.elsevier.com/xml/ani/ani" 
    xmlns:ani="http://www.elsevier.com/xml/ani/ani" 
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
    xmlns:ce="http://www.elsevier.com/xml/ani/common" 
    xmlns:ait="http://www.elsevier.com/xml/ani/ait"
    exclude-result-prefixes="ani">

  <xsl:output indent="yes" omit-xml-declaration="no"
       media-type="application/xml" encoding="UTF-8" />

  <xsl:template match="/">
    <searchresult>
      <xsl:apply-templates 
        select="/ani:bibdataset/ani:item/ani:bibrecord" />
    </searchresult>
  </xsl:template>

  <xsl:template match="ani:bibrecord">
    <document>
      <title><xsl:value-of select="ani:head/ani:citation-title/ani:titletext" /></title>
      <snippet>
          <xsl:value-of select="ani:head/ani:abstracts/ani:abstract/ce:para" />
      </snippet>
      <url>
        <xsl:variable name="doilink" select="ani:item-info/ani:itemidlist/ce:doi"/>
        <xsl:value-of 
          select="concat('http://dx.doi.org/', $doilink)" />
      </url>
    </document>
  </xsl:template>
</xsl:stylesheet>

请注意，您可以删除行xmlns="http://www.elsevier.com/xml/ani/ani"，但这意味着您的 searchresult （和其他）元素将在没有命名空间的情况下输出，因此您需要将其输出为{{ 1}}如果你想在给定的命名空间中使用它。

xslt没有显示结果。 xpath还是ns错了？

1 个答案: